使用VBA查詢目錄和目錄中的所有子文件夾，並返回特定文件擴展名的列A中的完整文件路徑

Question

我期望做的是列出具有特定擴展名的目錄及其子目錄中的所有文件如.PDB

，並返回這些結果說A列中

下面的代碼工作，但我不確定語法的使用只返回一個特定的文件擴展名類型。

Sub ListFiles() 
Const sRoot  As String = "Y:\Engineering\Database Versions\Chillers" 
Dim t As Date 

Application.ScreenUpdating = False 
With Columns("A:C") 
    .ClearContents 
    .Rows(1).Value = Split("File,Size,Date", ",") 
End With 

t = Timer 
NoCursing sRoot 
Columns.AutoFit 
Application.ScreenUpdating = True 
End Sub 

Sub NoCursing(ByVal sPath As String) 
Const iAttr  As Long = vbNormal + vbReadOnly + _ 
     vbHidden + vbSystem + _ 
     vbDirectory 
Dim col   As Collection 
Dim iRow  As Long 
Dim jAttr  As Long 
Dim sFile  As String 
Dim sName  As String 

If Right(sPath, 1) <> "\" Then sPath = sPath & "\" 

Set col = New Collection 
col.Add sPath 

iRow = 1 

Do While col.count 
    sPath = col(1) 

    sFile = Dir(sPath, iAttr) 

    Do While Len(sFile) 
     sName = sPath & sFile 

     On Error Resume Next 
     jAttr = GetAttr(sName) 
     If Err.Number Then 
      Debug.Print sName 
      Err.Clear 

     Else 
      If jAttr And vbDirectory Then 
       If Right(sName, 1) <> "." Then col.Add sName & "\" 
      Else 
       iRow = iRow + 1 
       If (iRow And &H3FF) = 0 Then Debug.Print iRow 
       Rows(iRow).Range("A1:C1").Value = Array(sName, _ 
                 FileLen(sName), _ 
                 FileDateTime(sName)) 
      End If 
     End If 
     sFile = Dir() 
    Loop 
    col.Remove 1 
Loop 
End Sub 

Answer 1

與下面的代碼更改Else...End If一部分，它只能與.pdb擴展打印文件。

'Your existing code 
Else 
    If InStr(1, sName, ".pdb", vbTextCompare) > 0 Then 
     iRow = iRow + 1 
     If (iRow And &H3FF) = 0 Then Debug.Print iRow 
     Rows(iRow).Range("A1:C1").Value = Array(sName, _ 
               FileLen(sName), _ 
               FileDateTime(sName)) 
    End If 
End If 
'Your existing code