轉換XML到合適的文本

Question

我有一個XML，看起來像這樣

<person> 
    <name> 
     <name-first>foo</name-first> 
     <name-last>bar</name-last> 
    </name> 
    <age>20</age> 
    <city>nowhere</city> 
</person> 

我想這個轉換成

person: 
    { 
    name: { 
      name-first:'foo', 
      name-last:'bar' 
      }, 
    age:'20', 
    city:'nowhere' 
    } 

在此先感謝。

Answer 1

下面是一個簡單的轉換 - 一開始：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="text"/> 
<xsl:strip-space elements="*"/> 

<xsl:param name="pIndents" select="' '"/> 

<xsl:template match="*[*]"> 
    <xsl:param name="pcurrentIndents" select="''"/> 
    <xsl:value-of select="concat($pcurrentIndents, name(), ':')"/> 
    <xsl:value-of select="concat('&#xA;',$pcurrentIndents, '{')"/> 
     <xsl:apply-templates> 
     <xsl:with-param name="pcurrentIndents" select= 
     "concat($pcurrentIndents, $pIndents)"/> 
     </xsl:apply-templates> 
    <xsl:value-of select="concat('&#xA;',$pcurrentIndents, '}')"/> 
</xsl:template> 

<xsl:template match="*[not(*)]"> 
    <xsl:param name="pcurrentIndents" select="''"/> 
    <xsl:text>&#xA;</xsl:text> 
    <xsl:value-of select="concat($pcurrentIndents, name(), ':')"/> 
    <xsl:apply-templates/> 
</xsl:template> 
</xsl:stylesheet> 

當這種轉變是在所提供的XML文檔應用：

<person> 
    <name> 
     <name-first>foo</name-first> 
     <name-last>bar</name-last> 
    </name> 
    <age>20</age> 
    <city>nowhere</city> 
</person> 

想要的，正確的結果產生：

person: 
{ name: 
    { 
    name-first:foo 
    name-last:bar 
    } 
    age:20 
    city:nowhere 
} 

說明：

1. 有匹配的元素有兩個模板。

2. 模板匹配*[*]匹配具有子元素的元素。它使用name()函數，:字符，NL字符，當前縮進（空格數）和{字符生成當前匹配元素的名稱。然後，將模板應用於當前匹配元素的子節點，參數$pcurrentIndents傳遞當前縮進，增加空間字符的預增量（如全局參數$pIndents中指定的那樣）。最後，在新行上使用當前縮進，最後的花括號是putput。

3. 匹配*[not(*)]（沒有任何元素作爲子元素的元素）的模板類似但更簡單。它輸出當前縮進處匹配元素的名稱和:字符。在這裏應用模板爲非元素節點調用XSLT內置模板 - 在這種情況下，將選擇與文本節點匹配的內置模板，並將文本節點複製到輸出。

Answer 2

你想要的是一個XML到JSON轉換器。

試試這個：http://www.thomasfrank.se/xml_to_json.html

Answer 3

這裏是一個應該給你如何將XML轉換爲所需的輸出一些想法的例子XSL模板：

<xsl:template match="person"> 
person: 
    { 
    name: { 
      name-first:<xsl:value-of select="name/name-first"/>, 
      name-last:<xsl:value-of select="name/name-last"/> 
      }, 
    age:<xsl:value-of select="age"/>, 
    city:<xsl:value-of select="city"/> 
    } 
</xsl:template> 

Answer 4

有許多的常規 - 可用於將XML轉換爲JSON輸出的多用途XSLT解決方案。

例如：

• http://code.google.com/p/xml2json-xslt/
• http://www.bramstein.com/projects/xsltjson/

我通過xml2json-xslt'sxml2json.xslt跑到你的XML並生成以下JSON輸出：

{ 
    "person": 
    { 
     "name": 
     { 
      "name-first":"foo", 
      "name-last":"bar" 
     }, 
     "age":20, 
     "city":"nowhere" 
     } 
}