如何使用awk提取引用字段？

我使用如何使用awk提取引用字段？

awk '{ printf "%s", $3 }'

來提取空格分隔行一些領域。當字段被引用內部的空閒空間時，我當然會得到部分結果。有任何機構可以提出解決方案嗎？

來源

2010-08-11 mmonem

顯示輸入文件format..and所需輸出！ – ghostdog74 2010-08-11 15:03:26

這實際上是相當困難的。我想出了以下awk腳本手動分割線與存儲陣列中的所有領域。

{ 
    s = $0 
    i = 0 
    split("", a) 
    while ((m = match(s, /"[^"]*"/)) > 0) { 
     # Add all unquoted fields before this field 
     n = split(substr(s, 1, m - 1), t) 
     for (j = 1; j <= n; j++) 
      a[++i] = t[j] 
     # Add this quoted field 
     a[++i] = substr(s, RSTART + 1, RLENGTH - 2) 
     s = substr(s, RSTART + RLENGTH) 
     if (i >= 3) # We can stop once we have field 3 
      break 
    } 
    # Process the remaining unquoted fields after the last quoted field 
    n = split(s, t) 
    for (j = 1; j <= n; j++) 
     a[++i] = t[j] 
    print a[3] 
}

來源

2010-08-11 14:31:09 schot

這是很複雜的解決方案。如果沒有簡單*一個行*的解決方案，我會去的perl – mmonem 2010-08-11 18:10:46

下次顯示您的輸入文件和所需的輸出。爲了得到引述領域，

$ cat file 
field1 field2 "field 3" field4 "field5" 

$ awk -F'"' '{for(i=2;i<=NF;i+=2) print $i}' file 
field 3 
field5

來源

2010-08-11 15:06:15 ghostdog74

其實這是Apache Web服務器日誌看來，AWK不能輕易地做到這一點 – mmonem 2010-08-11 18:09:48

@mmonem那麼這可能是有用的：。http://serverfault.com/questions/ 11028/DO-你具備的，任何-有用-AWK-和grep按腳本換解析-Apache的日誌 – schot 2010-08-12 11:15:07

這裏是一個可能的替代辦法解決這個問題。它通過查找以引號開頭或結尾的字段，然後將它們結合在一起來工作。在結束它更新的領域和NF，所以如果你把更多的模式，不合並一前一後，您可以使用過程一切正常awk的功能（新）領域。

我覺得這個使用POSIX awk中的唯一功能，不依賴於gawk的擴展，但我不能完全肯定。

# This function joins the fields $start to $stop together with FS, shifting 
# subsequent fields down and updating NF. 
# 
function merge_fields(start, stop) { 
    #printf "Merge fields $%d to $%d\n", start, stop; 
    if (start >= stop) 
     return; 
    merged = ""; 
    for (i = start; i <= stop; i++) { 
     if (merged) 
      merged = merged OFS $i; 
     else 
      merged = $i; 
    } 
    $start = merged; 

    offs = stop - start; 
    for (i = start + 1; i <= NF; i++) { 
     #printf "$%d = $%d\n", i, i+offs; 
     $i = $(i + offs); 
    } 
    NF -= offs; 
} 

# Merge quoted fields together. 
{ 
    start = stop = 0; 
    for (i = 1; i <= NF; i++) { 
     if (match($i, /^"/)) 
      start = i; 
     if (match($i, /"$/)) 
      stop = i; 
     if (start && stop && stop > start) { 
      merge_fields(start, stop); 
      # Start again from the beginning. 
      i = 0; 
      start = stop = 0; 
     } 
    } 
} 

# This rule executes after the one above. It sees the fields after merging. 
{ 
    for (i = 1; i <= NF; i++) { 
     printf "Field %d: >>>%s<<<\n", i, $i; 
    } 
}

上的輸入文件，如：

thing "more things" "thing" "more things and stuff"

它產生：

Field 1: >>>thing<<< 
Field 2: >>>"more things"<<< 
Field 3: >>>"thing"<<< 
Field 4: >>>"more things and stuff"<<<

來源

2014-09-01 12:11:55 benj

如果你只是尋找一個特定的字段，則

$ cat file 
field1 field2 "field 3" field4 "field5" 

awk -F"\"" '{print $2}' file

作品。它通過拆分」的文件，所以在上面的例子中，第二場是一個你想要的。

來源

2015-06-14 08:37:49

如何使用awk提取引用字段？

回答

相關問題