如何同步UWP應用程序與其後臺任務之間的資源訪問？

Question

在WP7應用程序中，我使用命名的互斥鎖來同步對StorageFiles和Tiles的訪問。 使用UWP應用程序的異步代碼時，這不再穩健，因爲互斥體是線程仿射的並與異步代碼混合，這會導致錯誤「對象同步方法是從未同步的代碼塊中調用的」。

Using mutex As New Threading.Mutex(False, "SyncAppAndBackTask") 
    Try 
     Await ... 
    Finally 
     mutex.ReleaseMutex() 
    End Try 
End Using 

在這裏不使用SemaphoreSlim，因爲應用程序和後臺任務運行在不同的進程中。

這個post建議使用Taks.Factory.StartNew與TaskCreationOptions.LongRunning或StaTaskScheduler。

LongRunning並未解決問題，因爲我的測試代碼證明了這一點，請參閱here。 我發現StaTaskScheduler的版本使用UWP中不可用的Thread類。

有人有一個解決方案，或至少一個UWP兼容版本的StaTaskScheduler - 在上述Noseratio提到「新線程」可以用Factory.StartNew替換。

作爲一種解決方法，我目前通過.OpenAsync（FileAccessMode.ReadWrite）使用存儲文件鎖定，但這會導致醜陋的重試循環。

Answer 1

隨着週年SDK同步的新獨立的處理模塊變得容易得多，因爲後臺處理不再在不同的進程中運行。我正在使用Stephen Clearey的AsyncEx中的AsyncLock。

原來的答案：

之類的語句「互斥是線程仿射，所以它們不與異步代碼工作」和錯誤在我的應用程序和測試都讓我懷疑，我們一般不能使用命名互斥體同步UWP應用程序與其後臺任務之間的資源訪問。我所看到的所有替代解決方案都只是在進行中。

只要.ReleaseMutex與.WaitOne（例如.WaitOne）編碼在同一水平上，我就得出結論認爲互斥體在這種情況下可以正常工作。而不是在.WaitOne之後等待的異步方法內）。

爲了編碼方便我封裝的互斥處理，允許使用的語句：

'Usage to serialize access: 
Using New AppAndBackgroundMutex(TimeSpan.FromSeconds(5)) 
    'Access storage files 
    'Access ApplicationData settings 
    'Update Tiles 
End Using 

'Usage to back out: 
Using New AppAndBackgroundMutex(TimeSpan.Zero) 
    '... 
End Using 

Public NotInheritable Class AppAndBackgroundMutex : Implements IDisposable 
    Private _mutex As Threading.Mutex 
    Private _iOwnMutex As Boolean 
    Sub New(waitTimeout As TimeSpan, Optional syncId As String = "SyncRates&Selections&Date") 
     Const UniqePartOfMutexName = "<app specific GUID>" 
     Try 
      _mutex = New Threading.Mutex(False, UniqePartOfMutexName & syncId) 
      _iOwnMutex = _mutex.WaitOne(waitTimeout) 
      If Not _iOwnMutex Then 
       Dim msg = ($"Unable to acquire mutex for app/background sync after waiting for {waitTimeout}.") 
       If waitTimeout = TimeSpan.Zero Then 
        'Intentionally backing out 
        Trace.Info(msg) 
       Else 
        Trace.Error(msg) 
       End If 
       Throw New MutexTimeoutException(msg) 
      End If 
     Catch ex As Threading.AbandonedMutexException 
      Trace.Error("Abandoned Mutex detected! OS might have killed background task. Ignoring problem.") 
      _iOwnMutex = True 
     End Try 
    End Sub 

    'Simple Dispose implementaion because class is sealed 
    Public Sub Dispose() Implements IDisposable.Dispose 
     If _iOwnMutex Then _mutex.ReleaseMutex() 
     _ mutex.Dispose() 
    End Sub 
End Class 

另外一個可以使用文件鎖定背出：

Try 
    Dim file = Await ApplicationData.Current.LocalFolder.CreateFileAsync("__AppAndBackgroundSync.lock", CreationCollisionOption.OpenIfExists) 
    Await file.OpenAsync(FileAccessMode.ReadWrite) 
    '... 
Catch ex As UnauthorizedAccessException 
    Throw New AppAndBackgroundConcurrencyViolationException() 
End Try 

Answer 2

如果我正確理解你，你正在尋找和異步鎖定。看看http://asynclock.codeplex.com。

Answer 3

你得到的異常，因爲你不與mutex.WaitOne（）阻塞線程，這樣你的互斥量沒有信號，因此你的代碼是不同步的，你會得到異常：

對象同步方法是從代碼不同步塊稱爲

嘗試這樣的：

Async Function TestMutex() As Task 
    Using mutex As New Threading.Mutex(False, "SyncAppAndBackTask") 
     Try 
      mutex.WaitOne() 
      For i = 1 To 3 
       Await SimulateCompute() 
       Debug.WriteLine(i) 
      Next 
     Catch ex As Exception 
      Debug.WriteLine(ex.Message) 
      Throw 
     Finally 
      mutex.ReleaseMutex() 
      Debug.WriteLine("success") 
     End Try 
    End Using 
End Function 

同樣在你的代碼中，你似乎正在使用TaskCountinuationOtions，無論是在StartNew它應該是TaskCreationOptions。雖然，無論是枚舉和LongRunning等於2.