我試圖證明Coq中的"Practical Coinduction"中的第一個示例。第一個例子是證明無限流整數上的詞典排序是可傳遞的。在Coq中證明Co-Inductive屬性(詞彙順序是傳遞性的)
我一直沒能制定的證明,以繞過Guardedness condition
這裏是我發展至今。首先是無限流的通常定義。然後定義稱爲lex
的詞典順序。最後,傳遞性定理的失敗證明。
Require Import Omega.
Section stream.
Variable A:Set.
CoInductive Stream : Set :=
| Cons : A -> Stream -> Stream.
Definition head (s : Stream) :=
match s with Cons a s' => a end.
Definition tail (s : Stream) :=
match s with Cons a s' => s' end.
Lemma cons_ht: forall s, Cons (head s) (tail s) = s.
intros. destruct s. reflexivity. Qed.
End stream.
Implicit Arguments Cons [A].
Implicit Arguments head [A].
Implicit Arguments tail [A].
Implicit Arguments cons_ht [A].
CoInductive lex s1 s2 : Prop :=
is_le : head s1 <= head s2 ->
(head s1 = head s2 -> lex (tail s1) (tail s2)) ->
lex s1 s2.
Lemma lex_helper: forall s1 s2,
head s1 = head s2 ->
lex (Cons (head s1) (tail s1)) (Cons (head s2) (tail s2)) ->
lex (tail s1) (tail s2).
Proof. intros; inversion H0; auto. Qed.
這裏是我想證明的引理。我首先準備目標,以便我可以應用構造函數,希望最終能夠使用cofix
中的「假設」。
Lemma lex_lemma : forall s1 s2 s3, lex s1 s2 -> lex s2 s3 -> lex s1 s3.
intros s1 s2 s3 lex12 lex23.
cofix.
rewrite <- (cons_ht s1).
rewrite <- (cons_ht s3).
assert (head s1 <= head s3) by (inversion lex12; inversion lex23; omega).
apply is_le; auto.
simpl; intros. inversion lex12; inversion lex23.
assert (head s2 = head s1) by omega.
rewrite <- H0, H5 in *.
assert (lex (tail s1) (tail s2)) by (auto).
assert (lex (tail s2) (tail s3)) by (auto).
apply lex_helper.
auto.
repeat rewrite cons_ht.
Guarded.
我該怎麼做?感謝任何提示!
- 編輯
感謝亞瑟(一如既往!)有益和有啓發答案,我也能完成的證明。我給我的版本以供參考。
Lemma lex_lemma : forall s1 s2 s3, lex s1 s2 -> lex s2 s3 -> lex s1 s3.
cofix.
intros s1 s2 s3 lex12 lex23.
inversion lex12; inversion lex23.
rewrite <- (cons_ht s1).
rewrite <- (cons_ht s3).
constructor; simpl.
inversion lex12; inversion lex23; omega.
intros; eapply lex_lemma; [apply H0 | apply H2]; omega.
Qed.
我用cons_ht
引理 「擴大」 的s1
和s3
值。這裏的lex
(與head
和tail
)的定義更接近Practical Coinduction中的逐字制定。 Arthur使用更優雅的技術,讓Coq自動擴展值 - 更好!