0
在NSIS接口配置文件ini中有多個RadioButton控件,如何使用group屬性對它們進行分組?這個屬性如何設置值?如何寫?幫我NSIS RadioButton如何分組
在NSIS接口配置文件ini中有多個RadioButton控件,如何使用group屬性對它們進行分組?這個屬性如何設置值?如何寫?幫我NSIS RadioButton如何分組
它說,在Install Options documentation如此吧!
GROUP:
這個標誌一組控件的第一個控件添加到組他們。分組控制允許您創建多組單選按鈕,並使用箭頭鍵更輕鬆地進行鍵盤導航。
NOTABSTOP:
在控制不要停止,當用戶按下Tab鍵。將NOTABSTOP添加到除第一個組以外的所有組的控件,以允許使用Tab鍵在組之間導航。
RequestExecutionLevel User
OutFile "test.exe"
Function .onInit
; Writing out the .ini manually here to keep the example in one source file
InitPluginsDir
WriteIniStr "$PluginsDir\MyPage.ini" Settings NumFields 4
WriteIniStr "$PluginsDir\MyPage.ini" "Field 1" Type RadioButton
WriteIniStr "$PluginsDir\MyPage.ini" "Field 1" Text G1:Radio1
WriteIniStr "$PluginsDir\MyPage.ini" "Field 1" Flags GROUP
WriteIniStr "$PluginsDir\MyPage.ini" "Field 1" State 1
WriteIniStr "$PluginsDir\MyPage.ini" "Field 1" Left 1
WriteIniStr "$PluginsDir\MyPage.ini" "Field 1" Right -1
WriteIniStr "$PluginsDir\MyPage.ini" "Field 1" Top 0
WriteIniStr "$PluginsDir\MyPage.ini" "Field 1" Bottom 10
WriteIniStr "$PluginsDir\MyPage.ini" "Field 2" Type RadioButton
WriteIniStr "$PluginsDir\MyPage.ini" "Field 2" Text G1:Radio2
WriteIniStr "$PluginsDir\MyPage.ini" "Field 2" Flags NOTABSTOP
WriteIniStr "$PluginsDir\MyPage.ini" "Field 2" Left 1
WriteIniStr "$PluginsDir\MyPage.ini" "Field 2" Right -1
WriteIniStr "$PluginsDir\MyPage.ini" "Field 2" Top 10
WriteIniStr "$PluginsDir\MyPage.ini" "Field 2" Bottom 20
WriteIniStr "$PluginsDir\MyPage.ini" "Field 3" Type RadioButton
WriteIniStr "$PluginsDir\MyPage.ini" "Field 3" Text G2:Radio1
WriteIniStr "$PluginsDir\MyPage.ini" "Field 3" Flags GROUP
WriteIniStr "$PluginsDir\MyPage.ini" "Field 3" Left 1
WriteIniStr "$PluginsDir\MyPage.ini" "Field 3" Right -1
WriteIniStr "$PluginsDir\MyPage.ini" "Field 3" Top 50
WriteIniStr "$PluginsDir\MyPage.ini" "Field 3" Bottom 60
WriteIniStr "$PluginsDir\MyPage.ini" "Field 4" Type RadioButton
WriteIniStr "$PluginsDir\MyPage.ini" "Field 4" Text G2:Radio2
WriteIniStr "$PluginsDir\MyPage.ini" "Field 4" Flags NOTABSTOP
WriteIniStr "$PluginsDir\MyPage.ini" "Field 4" State 1
WriteIniStr "$PluginsDir\MyPage.ini" "Field 4" Left 1
WriteIniStr "$PluginsDir\MyPage.ini" "Field 4" Right -1
WriteIniStr "$PluginsDir\MyPage.ini" "Field 4" Top 60
WriteIniStr "$PluginsDir\MyPage.ini" "Field 4" Bottom 70
FunctionEnd
Section
SectionEnd
Page Custom MyPage
Page InstFiles
Function MyPage
InstallOptions::dialog "$PluginsDir\MyPage.ini"
Pop $0
FunctionEnd
感謝你非常馬赫 – xinxinwang