打印TDBGrid

Question

如何在不安裝或下載組件的情況下打印DBGrid？

OR

我怎樣才能得到一個DBGrid的數據轉換成一個RichEdit的，這樣我可以通過它打印？

Answer 1

數據感知控件從DataSource屬性獲取它們的數據，使用它。您必須手動遍歷它，不可能立即（沒有第三方庫/組件）。

Answer 2

您可以循環進入您的網格並手動將它們全部放入您的RichEdit中。 但爲什麼要重新發明輪子。只需使用報告組件。 在delphi 7 - delphi2010上安裝了rave組件。

Answer 3

你需要能夠沿着這些路線制定出合適的打印寬度爲每個字段，東西：

function PrintFieldWidth(Field: TField): Integer; 
var 
    CharWidth: Integer; // an average character width 
    TitleWidth: Integer; // the width of the field title 
    FieldWidth: Integer; // the width of the field content 
begin 
    CharWidth := Printer.Canvas.TextWidth('0');     
    TitleWidth := Printer.Canvas.TextWidth(Field.DisplayName); 
    FieldWidth := Field.DisplayWidth*CharWidth;    
    if TitleWidth > FieldWidth then 
    Result := TitleWidth+CharWidth 
    else 
    Result := FieldWidth+CharWidth; 
end; 

通過所有的記錄然後循環，循環遍歷每個字段進行打印。

procedure PrintText(S: String; X, Y, W, H: Integer); 
begin 
    Printer.Canvas.TextRect(Rect(X,Y,X+W,Y+H),S); 
end; 

procedure PrintHeader(DataSet: TDataSet; X, Y, H: Integer); 
var 
    I: Integer; // record loop 
    W: Integer; // field width 
begin 
    for I := 0 to DataSet.FieldCount-1 do 
    begin 
    if DataSet.Fields[I].Visible then 
    begin 
     W := PrintFieldWidth(DataSet.Fields[I]); 
     PrintText(DataSet.Fields[I].FieldName, X, Y, W, H); 
     X := X + W; 
    end; 
    end; 
end; 

procedure PrintRecord(DataSet: TDataSet; X, Y, H: Integer); 
var 
    I: Integer; // record loop 
    W: Integer; // field width 
begin 
    for I := 0 to DataSet.FieldCount-1 do 
    begin 
    if DataSet.Fields[I].Visible then 
    begin 
     W := PrintFieldWidth(DataSet.Fields[I]); 
     PrintText(DataSet.Fields[I].AsString, X, Y, W, H); 
     X := X + W; 
    end; 
    end; 
end; 

procedure PrintDataSet(DataSet: TDataSet; X, Y: Integer); 
var 
    OldPos: TBookmark; 
    H: Integer; // line height 
begin 
    if DataSet <> nil then 
    begin 
    H := Printer.Canvas.TextHeight('0'); 
    SaveAfterScroll := DataSet.AfterScroll; 
    DataSet.AfterScroll := nil; 
    try 
     DataSet.DisableControls; 
     OldPos := DataSet.GetBookmark; 
     DataSet.First; 
     PrintHeader(DataSet, X, Y, H); 
     Y := Y + H * 2; 
     while not DataSet.Eof do 
     begin 
     PrintRecord(DataSet, X, Y, H); 
     Y := Y + H; 
     DataSet.Next; 
     end; 
     DataSet.GotoBookmark(OldPos); 
     DataSet.FreeBookmark(OldPos); 
    finally 
     DataSet.AfterScroll := SaveAfterScroll; 
     DataSet.EnableControls; 
    end; // try 
    end; 
end; 

您需要添加一些代碼來處理分頁符。