在功率樞軸或功率查詢創建彙總表

Question

系統：Excel中2013

一個主文件已被設置成多列，包括1個ID列和2個日期欄（創建日期和發佈日期）創建。

ID  CreateDate Release Date 
124520 04/09/2015 05/09/2015 
228551 05/09/2015 07/09/2015 
228552 06/09/2015 08/09/2015 

如何使用PowerPivot或PowerQuery創建如下所示的摘要表？

Date  NumOfIDsCreated  NumOfIDsReleased 
04/09/2015 1     0 
05/09/2015 1     1 
06/09/2015 1     0 
07/09/2015 0     1 
08/09/2015 0     1 

目前，我在Excel中創建該表有兩個的PowerPivot表（帶日期和次數），並與所有的日期一個單獨的表從兩個PowerPivot的表運行查詢。有沒有更好的方法來做到這一點？

Answer 1

這裏是你的表

關鍵的一點是轉換的另一種方式 - 使用可計算的紀錄group_by_date。

let 
    src = Excel.CurrentWorkbook(){[Name="Table1"]}[Content], 
    change_types = Table.TransformColumnTypes(src,{{"CreateDate", type date}, {"ReleaseDate", type date}}), 
    unpivot = Table.UnpivotOtherColumns(change_types, {"ID"}, "attr", "value"), 
    group_by_date = Table.Group(unpivot, {"value"}, {{"rec", each 
    [ 
     NumOfIDsCreated=List.Count(List.Select([attr], each _="CreateDate")), 
     NumOfIDsReleased=List.Count(List.Select([attr], each _="ReleaseDate")) 
    ]}}), 
    expand = Table.ExpandRecordColumn(group_by_date, "rec", {"NumOfIDsCreated", "NumOfIDsReleased"}, {"NumOfIDsCreated", "NumOfIDsReleased"}), 
    sort = Table.Sort(expand,{{"value", Order.Ascending}}) 
in 
    sort 

Answer 2

如果要創建這個作爲電力透視模型中的表，那麼電源查詢是在2016年前去電樞紐版本的方式，有跡象表明另一個答案。

如果你使用2016+（這個功能應該出現在GA版本的Excel，從我所聽到的）或Power BI桌面應用，在模型中，那麼你可以創建計算表使用DAX：

假設FactTable [CreateDate]和DimDate [Date]之間的活動關係以及FactTable [ReleaseDate]和DimDate [Date]之間的非活動關係。

CreateDateCount:= // Note this is a measure 
COUNTROWS(FactTable) 

ReleaseDateCount:= // also a measure 
CALCULATE(
    COUNTROWS(FactTable) 
    ,USERELATIONSHIP(FactTable[ReleaseDate], DimDate[Date]) 
) 

SummarizedFact= // note this is a calculated table 
FILTER(
    ADDCOLUMNS(
     DimDate 
     ,"IDsCreated" 
     ,[CreateDateCount] 
     ,"IDsReleased" 
     ,[ReleaseDateCount] 
    ) 
    ,[IDsCreated] || [IDsReleased] 
) 

最後，我不知道爲什麼，這需要存在作爲模型中的一個表，因爲它似乎是一個需要報告，並通常在電源透視模型，你會做透視表這項工作，而不是在PP模型中。如果這是您真正需要的用例，那麼我上面寫的措施也適用於此。