Excel的VBA - 從工作表Sheet1

Question

搜索在Sheet2中，並更新與相鄰的價值Sheet1中值我嘗試寫一些VBA代碼，會第一時間值唯一值的列表，在A列Sheet 2上並搜索其反對sheet1中A列中的唯一值。一旦找到，它就會將單元格6更新爲sheet1上活動單元格的右側，其值與sheet2中的唯一代碼相鄰。它將繼續，在表2中列出其餘的表格，直到它到達一個空白單元格。

我已經成功地獲取代碼，找到獨特的價值觀，然後通過添加1更新單元6的權利，但我不能工作了其他位：

Private Sub SinglePaste_Click() 
    On Error GoTo InvalidBarcode 
    Dim EAN As Range 
     Sheets("Paste Here").Select 
      For Each EAN In ActiveSheet.Range("A:A") 
      Sheets("Master Stock File").Select 
      With Worksheets("Master Stock File") 
      .Range("A:A").Find(What:=EAN, After:=.Range("A1"), LookIn:=xlFormulas, _ 
      LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _ 
      MatchCase:=False).Activate 
     ActiveCell.Offset(0, 6).Select 
     ActiveCell.Value = ActiveCell.Value + 1 
     End With 
     If IsEmpty(EAN) Then Exit For 
     Next EAN 
    Exit Sub 
    InvalidBarcode: 
    MsgBox ("Invalid Barcode - " & "" & EAN) 
    End Sub 

這是否合理？任何幫助是極大的讚賞。

Answer 1

你的代碼使用了大量的ActiveSheet，ActiveCell和Select來表示宏記錄器，通常效率較低。我仍然不知道「另一位」你指的是，但這裏是一個重新設計的宏：

Public Sub NewSinglePaste_Click() 
    Dim EAN As Range 
    Dim FoundRange As Range 
    Dim ValueCell As Range 
    Dim MasterSheet As Worksheet 
    Dim PasteSheet As Worksheet 

    Set MasterSheet = Sheets("Master Stock File") 
    Set PasteSheet = Sheets("Paste Here") 

    On Error GoTo InvalidBarcode 
    For Each EAN In PasteSheet.Range("A:A") 
    If IsEmpty(EAN.Text) Or EAN.Text = "" Then Exit For 

    Set FoundRange = MasterSheet.Range("A:A").Find(What:=EAN, _ 
     After:=MasterSheet.Range("A1"), LookIn:=xlFormulas, LookAt:=xlPart, _ 
     SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False) 

    If Not (FoundRange Is Nothing) Then 
     Set ValueCell = FoundRange.Offset(0, 6) 
     ValueCell.Value = ValueCell.Value + 1 
    Else 
     Debug.Print "Cell not found: " & EAN.Worksheet.Name & "!" & EAN.Address 
    End If 
    Next EAN 

    Exit Sub 

InvalidBarcode: 
    MsgBox ("Invalid Barcode - " & "" & EAN) 

End Sub