自定義組件和標籤順序

Question

我有一個自定義組件（繼承自TCustomPanel），它由兩個其他組件（假設兩個編輯）組成。如何在使用組件時正確地獲取Tab鍵順序？

在Tab鍵順序設計器中，我只能訪問組件本身，因爲它是一個面板，所以不能擁有焦點。運行時會發生什麼情況是，我可以使用Tab鍵訪問編輯，但只有在組件下方的兩個按鈕得到了重點之後才能訪問。

如何在這種情況下更改標籤順序？

Answer 1

組件中嵌套控件的Tab順序不同於組件所在表單的Tab順序。當您選擇嵌套控件時，表單的標籤順序列表中組件的標籤順序。一旦所有選項卡順序列表組合時，它們導致最終循環：

• 窗體上的控制（TabOrder=0）
• 另一個上表單控件（TabOrder=1）
• 你的面板部件（TabOrder=2）
  • 編輯1（TabOrder=0）
  • 編輯2（TabOrder=1）
• 上形式的另一個控制（TabOrder=3）

---

爲了能夠設置的面板構件設計時的Tab鍵順序：

• 使用在設計選項卡順序編輯器（右鍵點擊在組件的父級上），並使用編輯器中的箭頭更改Tab鍵順序，或者

• 發佈組件的TabOrder屬性並將其設置在對象檢查器中：

  type 
      TMyPanel = class(TCustomPanel) 
      published 
      property TabOrder; 
      end; 
  

在運行時，它總是可以設置組件的選項卡順序，因爲TabOrder屬性聲明公衆TWinControl。

...因爲是面板所以不能集中注意力。

不，面板可以重點聚焦就好，但不會默認。這是通過TabStop屬性處理的，默認爲False。您不希望TabStop爲您的組件設置True，因爲（1）面板沒有指示器，它具有焦點，（2）它不是我想要的（我想象）。

---

更改嵌套控件的Tab順序最好在組件的構造函數或運行時完成。

爲了能夠在設計時設置組件內嵌套控件的Tab順序，需要做更多的工作。 我不認爲你想這樣做，但由於我以前的答案（刪除）是垃圾（並且蠻橫地投票），我已經制定了一個例子作爲補償。

首先，請注意，使用設計器中的Tab鍵順序編輯器（右鍵單擊面板組件）設置這些編輯的Tab鍵順序將更改Tab鍵順序，但不會持續。這是因爲這些更改沒有流式傳輸到DFM。

爲了能夠流/保存控件的設計時間的變化，你需要把它們發佈：

type 
    TMyPanel = class(TCustomPanel) 
    private 
    FEdit1: TEdit; 
    FEdit2: TEdit; 
    public 
    constructor Create(AOwner: TComponent); override; 
    published 
    property Edit1: TEdit read FEdit1; 
    property Edit2: TEdit read FEdit2; 
    end; 

constructor TMyPanel.Create(AOwner: TComponent); 
begin 
    inherited Create(AOwner); 
    FEdit1 := TEdit.Create(Self); 
    FEdit1.SetBounds(10, 10, 100, 21); 
    FEdit1.Name := 'Edit1'; 
    FEdit1.Parent := Self; 
    FEdit1.SetSubComponent(True); 
    FEdit2 := TEdit.Create(Self); 
    FEdit2.SetBounds(10, 41, 100, 21); 
    FEdit2.Name := 'Edit2'; 
    FEdit2.Parent := Self; 
    FEdit2.SetSubComponent(True); 
end; 

當然這個發佈這些控件的所有屬性，現在用戶可以更改爲所欲爲。爲了防止這種情況，考慮限制TEdit控件的發佈性能：

unit MyPanelEdit; 

interface 

uses 
    DesignEditors, Unit2, DesignIntf, SysUtils, Classes, TypInfo, StdCtrls; 

type 
    TEditProperty = class(TComponentProperty) 
    private 
    function FilterFunc(const ATestEditor: IProperty): Boolean; 
    public 
    function GetAttributes: TPropertyAttributes; override; 
    procedure GetProperties(Proc: TGetPropProc); override; 
    end; 

procedure Register; 

implementation 

procedure Register; 
begin 
    RegisterPropertyEditor(TypeInfo(TEdit), TMyPanel, '', TEditProperty); 
end; 

{ TEditProperty } 

function TEditProperty.FilterFunc(const ATestEditor: IProperty): Boolean; 
begin 
    Result := ATestEditor.GetName = 'TabOrder'; 
end; 

function TEditProperty.GetAttributes: TPropertyAttributes; 
begin 
    Result := [paSubProperties]; 
end; 

procedure TEditProperty.GetProperties(Proc: TGetPropProc); 
var 
    LComponents: IDesignerSelections; 
    LDesigner: IDesigner; 
begin 
    LComponents := GetSelections; 
    if LComponents <> nil then 
    begin 
    if not Supports(
     FindRootDesigner(LComponents[0]), IDesigner, LDesigner) then 
     LDesigner := Designer; 
    GetComponentProperties(LComponents, [tkInteger], LDesigner, Proc, 
     FilterFunc); 
    end; 
end; 

end. 

這限制了出版TEdit屬性的屬性唯一TabOrder顯現。