Event.clone和Event.toString示例？

Question

任何人都可以提供或多或少的真實世界的例子，你可能想要實際使用這兩種Event類的方法嗎？

AS 3使我們覆蓋了擴展事件的任何自定義類中的這些方法，但我不知道爲什麼。

Answer 1

toString - 我只用它來調試消息，但在這些情況下，如果您不覆蓋toString，那麼您將無法返回事件的字符串表示形式。考慮下面這個例子，其中單處理器用於捕獲各種事件類型：

function handleEvents(evt:*):void 
{ 
    //trace the event type and all parameters including extra parameters from custom events 
    trace(evt.toString()); 
} 

克隆 - 如果您需要重新派遣一個事件，事件類的clone方法將被調用。這將返回一個新的事件對象，並將目標重新分配給新的調度對象。問題是，如果您不覆蓋克隆方法，clone會從最後一個定義它的類中創建一個新的事件對象，而不是從您的自定義事件類中創建。當您捕獲重新分派的事件時，這很可能會導致類型錯誤。

Answer 2

我從來沒有重寫過它們，並且每當它被保證時我總是使用自定義事件？

Answer 3

增加shanethehat的toString解釋，如果不重寫toString和跟蹤事件，它會永遠打印的一般Event默認信息，因爲它是你的自定義事件是什麼子類。

覆蓋toString用於調試，所以它不是必要的，雖然它是鼓勵，特別是如果你分發你的API，與其他開發人員一起工作，或者只是想編寫乾淨，一致的代碼。

根據自定義事件中的屬性數量，可以創建一個switch語句，以便toString僅爲每種類型返回適當的事件屬性。下面是從我HistoryEvent類這樣的例子：

package com.mattie.events 
{ 
    //Imports 
    import flash.events.Event; 

    //Class 
    public class HistoryEvent extends Event 
    { 
     //Constants 
     public static const CHANGE:String = "change"; 
     public static const STATUS:String = "status"; 

     //Variables 
     public var action:String; 
     public var name:String; 
     public var data:Object; 
     public var undoable:Boolean; 
     public var undoableName:String; 
     public var redoable:Boolean; 
     public var redoableName:String; 
     public var index:uint; 

     //Constructor 
     public function HistoryEvent(type:String, action:String = null, name:String = null, data:Object = null, undoable:Boolean = false, undoableName:String = null, redoable:Boolean = false, redoableName:String = null, index:uint = 0) 
     { 
      super(type); 

      this.action = action; 
      this.name = name; 
      this.data = data; 
      this.undoable = undoable; 
      this.undoableName = undoableName; 
      this.redoable = redoable; 
      this.redoableName = redoableName; 
      this.index = index; 
     } 

     //Override clone 
     override public function clone():Event 
     { 
      return new HistoryEvent(type, action, name, data, undoable, undoableName, redoable, redoableName, index); 
     } 

     //Override toString 
     override public function toString():String 
     { 
      switch (type) 
      { 
       case CHANGE: return formatToString("HistoryEvent", "type", "action", "name", "data"); 
       case STATUS: return formatToString("HistoryEvent", "type", "undoable", "undoableName", "redoable", "redoableName", "index"); 
       default:  return null; 
      } 
     } 
    } 
}