如何使非模態對話框始終位於頂部？

Question

我在我的應用程序中使用Dialog {}的一個實例來顯示一個小的控制器窗口，用戶可以通過這個窗口進行交互以影響主窗口中的功能（排序遙控器）。我可以製作這個對話框模式（modality: Qt.WindowModal或modality: Qt.ApplicationModal），或者我可以用modality: Qt.NonModal使它成爲非模態。

我的問題是，我需要使它非模態，但始終在主窗口的頂部。如果我使用Qt.NonModal，我仍然可以點擊主窗體，但是隨後我的對話框會出現在它後面。 Dialog類似乎沒有flags:屬性，所以我不能將它設置爲Qt.WindowsStaysOnTopHint。

有沒有什麼辦法像這樣純粹從QML端設置一個Dialog的標誌？或者是否有可能在C++中編寫一個簡單的實用程序方法，我可以從我的Dialog的Component.onCompleted:調用並傳入對話框以在其中設置窗口標誌？

更新：說明一下我說的，這是我在我的主窗口頂部的對話框：

這裏是我的對話我的主窗口下方：

我希望我的對話框不會像這樣在我的主窗口下面，但我仍然希望能夠點擊並與我的主窗口進行交互。換句話說，我希望我的對話框是非模態的，但始終處於頂部。

Answer 1

嘗試使用Window而不是Dialog這種方式，您將有權訪問flags屬性。

您可以將flags設置爲Qt.WindowStaysOnTopHint，讓您的窗口始終位於其他窗口之上。你可以找到標記列表here。（不要忘記.在QML更換::）

Main.qml：

import QtQuick 2.5 
import QtQuick.Controls 2.0 
import QtQuick.Dialogs 1.2 

ApplicationWindow { 
    visible: true 
    width: 640 
    height: 480 
    title: qsTr("Hello World") 


    Button { 
     id: btn 
     width: 100 ; height : 40 
     text: "click me" 
    } 

    Text { 
     anchors.top : btn.bottom 
     text: "Button currently pressed" 
     visible: btn.pressed 
    } 

    DialogOnTop { 

    } 
} 

DialogOnTop.qml：

import QtQuick 2.0 
import QtQuick.Window 2.0 
import QtQuick.Controls 1.4 

Window { 
    id: myWindow 

    width: 200 
    height: 200 

    flags: Qt.Window | Qt.WindowSystemMenuHint 
      | Qt.WindowTitleHint | Qt.WindowMinimizeButtonHint 
      | Qt.WindowMaximizeButtonHint | Qt.WindowStaysOnTopHint 


    visible: true 
    modality: Qt.NonModal // no need for this as it is the default value 


    Rectangle { 
     color: "lightskyblue" 
     anchors.fill: parent 
     Text { 
      text: "Hello !" 
      color: "navy" 
      anchors.centerIn: parent 
     } 
    } 
} 

結果：

Answer 2

好的，你只需要創建一個對話框（或者看起來像一個對話框的組件），並且只想與主窗口和交互對話框窗口。

請嘗試以下方法：

main.qml

import QtQuick 2.7 
import QtQuick.Controls 2.0 
import QtQuick.Layouts 1.0 

ApplicationWindow { 
    id: rootWindow 
    visible: true 
    width: 640 
    height: 480 
    title: qsTr("Hello World") 

    color: "green" 

    Rectangle { 
     id: behind 
     anchors.fill: parent 
     color: Qt.rgba(0, 0, 0, 0.7) 
     visible: false 
    } 

    MouseArea { 
     enabled: behind.visible 
     anchors.fill: parent 

     onClicked: { 
      console.log("Root Window") 
     } 
    } 

    Button { 

     text: "Open Dialog" 

     onClicked: { 
      behind.visible = true; 
      var comp = Qt.createComponent("qrc:/MyDialog.qml"); 
      // var comp = Qt.createComponent("qrc:/DialogQt.qml"); 
      var obj1 = comp.createObject(rootWindow, {}); 
      obj1.z = 2; 
     } 
    } 
} 

MyDialog.qml

import QtQuick 2.7 

Rectangle { 
    id: modalWindow 
    width: 200 
    height: 200 
    color: "red" 

    anchors.centerIn: parent 

    MouseArea { 
     anchors.fill: parent 
     onClicked: { 
      console.log("Modal Window") 
     } 
    } 
} 

點擊 '打開對話框' 按鈕將創建並打開 '模式' 對話框主窗口組件的頂部。

當然，您必須調整「MyDialog.qml」文件以適合您自己的設計要求。

但是，使用此作爲一個「真正的」對話也沒有工作，（我）像通用已經在評論部分中指出：

DialogQt.qml

Dialog { 
    visible: true 
    title: "Blue sky dialog" 

    modality : Qt.ApplicationModal 

    contentItem: Rectangle { 
     color: "lightskyblue" 
     anchors.fill: parent 
     Text { 
      text: "Hello blue sky!" 
      color: "navy" 
      anchors.centerIn: parent 
     } 
    } 

} 

Answer 3

通常要使用Dialog不僅僅是創建一個新的窗口，但其實現的功能和界面...

該Dialog不繼承Window或ApplicationWindow是顯而易見的原因是：有沒有窗戶，只要它不是open()。但是，一旦它是開放的，有一個ApplicationWindow（從QtQuick.Controls 1.4）現在

，在文檔中，我們發現這個漂亮attatched屬性：ApplicationWindow這是提供給每一個Item，並方便它允許我們訪問這個窗口。然後，我們只需要找到一種方法，一旦ApplicationWindow變爲可用，即設置正確的標誌 - 例如，當我們得到信號visibleChanged。
由於Dialog不是Item，我們需要使用其contentItem來訪問此附加屬性。

當我們把所有這些共同作用的結果可能是這樣的：

NonModalDialogThatStaysOnTop.qml//我吸在命名

import QtQuick 2.3 
import QtQuick.Controls 1.4 // You need this, to have access to the `ApplicationWindow`-attatched property 
import QtQuick.Dialogs 1.2 

Dialog { 
    onVisibleChanged: { 
     if (visible) contentItem.ApplicationWindow.window.flags |= Qt.WindowStaysOnTopHint 
    } 
    modality: "NonModal" 
} 

現在，你有你喜歡的那Dialog保持在頂部，但不是模態。