區分「文件不存在」和「拒絕訪問」

Question

在VBScript中，我想知道文件是否存在：

Set fso = CreateObject("Scripting.FileSystemObject") 
If Not (fso.FileExists(file)) Then 
    msg = " doesn't exist." 
End If 

我的文件是內部網絡上。

有沒有辦法來區分：

• 文件確實不存在
• 拒絕訪問

我嘗試用fso.OpenTextFile但對於這兩種情況下，結果總是：Err.Number = 5.

Answer 1

區分您需要的不存在的和不可訪問的文件.FileExists 和個.OpenTextFile：

Option Explicit 

Dim goFS : Set goFS = CreateObject("Scripting.FileSystemObject") 

Function ReadFile(p, ByRef m) 
    If goFS.FileExists(p) Then 
    Dim aErr 
    On Error Resume Next 
     Set ReadFile = goFS.OpenTextFile(p) 
     aErr = Array(Err.Number, Err.Description) 
    On Error GoTo 0 
    If aErr(0) Then 
     m = p & " - " & aErr(1) 
     Set ReadFile = Nothing 
    Else 
     m = "" 
    End If 
    Else 
    Set ReadFile = Nothing 
    m = p & " - no such file" 
    End If 
End Function 

Dim p, m 
For Each p In Split("e:\roots.own e:\nosuchfile e:\dirsbf.tmp") 
    Dim tsIn : Set tsIn = ReadFile(p, m) 
    If tsIn Is Nothing Then 
     WScript.Echo "fail", m 
    Else 
     ' read from tsIn 
     tsIn.Close 
     WScript.Echo "ok" 
    End If 
Next 

輸出：

cscript 35338634.vbs 
fail e:\roots.own - Permission denied 
fail e:\nosuchfile - no such file 
ok 

由於安斯加爾的觀察，該功能可以改進：

Function ReadFile(p, ByRef m) 
    Dim aErr 
On Error Resume Next 
    Set ReadFile = goFS.OpenTextFile(p) 
    aErr = Array(Err.Number, Err.Description) 
On Error GoTo 0 
    If aErr(0) Then 
    m = p & " - " & aErr(1) 
    Set ReadFile = Nothing 
    Else 
    m = "" 
    End If 
End Function