如何獲取有關計算機的信息？ [32位或64位]

Question

我如何獲得有關Windows操作系統類型的信息？它是32位還是64位？我如何以編程方式獲取這些信息？

Answer 1

您需要使用GetProcAddress()在運行時檢查IsWow64Process()功能的可用性，就像這樣：

function Is64BitWindows: boolean; 
type 
    TIsWow64Process = function(hProcess: THandle; var Wow64Process: BOOL): BOOL; 
    stdcall; 
var 
    DLLHandle: THandle; 
    pIsWow64Process: TIsWow64Process; 
    IsWow64: BOOL; 
begin 
    Result := False; 
    DllHandle := LoadLibrary('kernel32.dll'); 
    if DLLHandle <> 0 then begin 
    pIsWow64Process := GetProcAddress(DLLHandle, 'IsWow64Process'); 
    Result := Assigned(pIsWow64Process) 
     and pIsWow64Process(GetCurrentProcess, IsWow64) and IsWow64; 
    FreeLibrary(DLLHandle); 
    end; 
end; 

，因爲該功能僅適用於那些有一個64位的味道Windows版本。聲明它爲external將阻止您的應用程序在SP2以前的Windows 2000或Windows XP上運行。

編輯：

克里斯已經張貼了關於緩存出於性能的考慮結果的評論。對於這個特定的API函數，這可能不是必需的，因爲kernel32.dll將一直存在（並且我無法想象一個程序甚至會在沒有它的情況下加載），但對於其他函數，情況可能不同。因此，這裏的是緩存功能結果的版本：

function Is64BitWindows: boolean; 
type 
    TIsWow64Process = function(hProcess: THandle; var Wow64Process: BOOL): BOOL; 
    stdcall; 
var 
    DLLHandle: THandle; 
    pIsWow64Process: TIsWow64Process; 
const 
    WasCalled: BOOL = False; 
    IsWow64: BOOL = False; 
begin 
    if not WasCalled then begin 
    DllHandle := LoadLibrary('kernel32.dll'); 
    if DLLHandle <> 0 then begin 
     pIsWow64Process := GetProcAddress(DLLHandle, 'IsWow64Process'); 
     if Assigned(pIsWow64Process) then 
     pIsWow64Process(GetCurrentProcess, IsWow64); 
     WasCalled := True; 
     FreeLibrary(DLLHandle); 
    end; 
    end; 
    Result := IsWow64; 
end; 

緩存此功能結果安全的，因爲API函數要麼是有或沒有，其結果不能在同一個Windows安裝改變。甚至可以安全地從多個線程同時調用它，因爲找到WasCalled爲False10的兩個線程都將調用該函數，將相同的結果寫入相同的內存位置，並且之後僅將WasCalled設置爲True。

Answer 2

如果a）你在windows和b）你可以訪問註冊表，那麼HKEY_LOCAL_MACHINE \ SOFTWARE \ Microsoft \ Windows NT \ CurrentVersion應該是提供信息的。

Answer 3

我不知道如何在Delphi中調用Win32函數。

但是，如果您編寫一個32位程序，您可以調用Win32 API IsWow64Process來了解您是否在64位操作系統中。

當然，如果你編寫一個64位的exe文件，它只能運行在64位的Windows上，所以不需要問。

Answer 4

function IsWin64: Boolean; 
var 
    IsWow64Process : function(hProcess : THandle; var Wow64Process : BOOL): BOOL; stdcall; 
    Wow64Process : BOOL; 
begin 
    Result := False; 
    IsWow64Process := GetProcAddress(GetModuleHandle(Kernel32), 'IsWow64Process'); 
    if Assigned(IsWow64Process) then begin 
    if IsWow64Process(GetCurrentProcess, Wow64Process) then begin 
     Result := Wow64Process; 
    end; 
    end; 
end; 

Answer 5

除了IsWow64Process，將GetNativeSystemInfo API函數可能是你的興趣（它在Windows單元定義），以瞭解更多有關你的CPU（或者你可以使用裝配和CPUID）。

Answer 6

//沒有測試但你可以試試這個

is64 := (Environment.GetEnvironmentVariable('ProgramW6432') <> ''); 

Answer 7

德爾福XE +

Uses System.SysUtils 

Function IsWin64Or32: string; 
Begin 
    if Pos('64-bit', TOSVersion.ToString) > 0 then 
    Result := '64-bit' 
    Else 
    Result := '32-bit'; 
End; 

例

lbl1.Caption := IsWin64Or32; 

Answer 8

function TForm2.Arch: string; 
begin 
if TOSVersion.Architecture=arIntelX86 then 
    Result := '32-bit' Else Result := '64-bit' 
end;