VBScript和批處理交互

Question

我正在運行批處理腳本和用戶必須訪問數據庫的某處。

此時，用vbscript製作的窗口會提示要求用戶輸入登錄名和密碼。 （確定，取消按鈕）

如果OK後的憑證是正確的，則該批次將按照planA繼續，否則批次將執行其他操作到planB。如果（取消），它會返回到批次和主菜單。

這就是我一直在掙扎：

@echo off 

:Ini 
echo [1] Access database 
echo [2] Main menu 
echo: 
set /p Quest= What do you prefer (1/2)?   
if not '%Quest%'=='' set Quest=%Quest:~0,1% 
if '%Quest%'=='1' goto VBS 
if '%Quest%'=='2' goto BATCH 
echo Invalid option, please try again 
cls 
goto Ini 

:BATCH 
echo Heading for main menu ... 
goto Main 

:VBS 
:wscript.echo InputBox("Enter your password","VBScript-Batch") 
findstr "^:" "%~sf0" | findstr /i /v ":Label" >temp.vbs 
for /f "delims=" %%N in ('cscript //nologo temp.vbs') do set pass=%%N 
del temp.vbs 

:Label1 

If %pass%=="okay" echo Valid Password ! & goto PLAN-A 
If not %pass%=="okay" echo Invalid Password !! & goto PLAN-B 

:PLAN-A 
echo continue from here 

:PLAN-B 
echo do something else 

（...）

- 如何獲取用戶信息，驗證它，回到批對於計劃A或計劃B？

正如你看到的，如果我們消除「& goto PLAN」的東西的腳本工作。它將VBS輸入「pass」發送到批處理，批處理回聲「繼續從這裏開始」或「執行其他操作」，其餘代碼應該從同一批處理中繼續。

但是，它不工作...任何幫助，使這個真的工作？

Answer 1

您的主要問題是您沒有正確設置文件以便於從批處理文件中提取VBS。您的VBS看起來與批次標籤沒有區別。你過濾掉了「標籤」標籤，但你仍然包含:ini,:BATCH等行。顯然這些會使VBS絆倒。我通過在您的VBS前加上:::並調整您的過濾器來解決問題。沒有必要明確地過濾掉任何標籤。我選擇了3個冒號，因爲單個冒號用於標籤，而2個冒號經常用於註釋。只需通過改變前面冒號的數量，就可以在批處理中嵌入多個獨立的VBS腳本。

我也調整了代碼的一小部分，並撒在一些EXIT/B語句，以便代碼不會經歷。另外你的：MAIN沒有定義，所以我將GOTO註釋掉了，並用EXIT/B代替它。

@echo off 
:Ini 
echo [1] Access database 
echo [2] Main menu 
echo: 
set /p Quest= What do you prefer (1/2)? 
if not '%Quest%'=='' set Quest=%Quest:~0,1% 
if '%Quest%'=='1' goto VBS 
if '%Quest%'=='2' goto BATCH 
echo Invalid option, please try again 
cls 
goto Ini 

:BATCH 
echo Heading for main menu ... 
::goto Main 
exit /b 

:VBS 
:::wscript.echo InputBox("Enter your password","VBScript-Batch") 
findstr "^:::" "%~sf0" >temp.vbs 
for /f "delims=" %%N in ('cscript //nologo temp.vbs') do set pass=%%N 
del temp.vbs 
If "%pass%"=="okay" (
    echo Valid Password ! 
    goto PLAN-A 
) else (
    echo Invalid Password !! 
    goto PLAN-B 
) 

:PLAN-A 
echo continue from here 
exit /b 

:PLAN-B 
echo do something else 
exit /b