在抽象謂詞

Question

我想出來的行使下列事實

byCar(auckland,hamilton). 
byCar(hamilton,raglan). 
byCar(valmont,saarbruecken). 
byCar(valmont,metz). 

byTrain(metz,frankfurt). 
byTrain(saarbruecken,frankfurt). 
byTrain(metz,paris). 
byTrain(saarbruecken,paris). 

byPlane(frankfurt,bangkok). 
byPlane(frankfurt,singapore). 
byPlane(paris,losAngeles). 
byPlane(bangkok,auckland). 
byPlane(singapore,auckland). 
byPlane(losAngeles,auckland). 

開始...並要求讀者定義謂詞travel/3這樣，例如，

travel(valmont, losAngeles, T) 

...會找到像這樣的解決方案

T = go(byCar(valmont, metz), 
     go(byTrain(metz, paris), 
      go(byPlane(paris, losAngeles)))). 

這是我想到的：

travel(X,Y,go(byCar(X,Y))):-byCar(X,Y). 
travel(X,Y,go(byTrain(X,Y))):-byTrain(X,Y). 
travel(X,Y,go(byPlane(X,Y))):-byPlane(X,Y). 

travel(X,Z,go(byCar(X,Y),T)):-byCar(X,Y),travel(Y,Z,T). 
travel(X,Z,go(byTrain(X,Y),T)):-byTrain(X,Y),travel(Y,Z,T). 
travel(X,Z,go(byPlane(X,Y),T)):-byPlane(X,Y),travel(Y,Z,T). 

看來工作...

?- travel(valmont, losAngeles, X). 
X = go(byCar(valmont, saarbruecken), go(byTrain(saarbruecken, paris), go(byPlane(paris, losAngeles)))) ; 
X = go(byCar(valmont, metz), go(byTrain(metz, paris), go(byPlane(paris, losAngeles)))) ; 
false. 

...但它傷害了我的眼睛;所有這些重複都是抽象的呼喊。

我試圖通過定義

oneLeg(X,Y):-byCar(X,Y);byTrain(X,Y);byPlane(X,Y). 

...並重新定義，以消除重複travel/3爲

travel(X,Y,go(oneLeg(X,Y))):-oneLeg(X,Y). 
travel(X,Z,go(oneLeg(X,Y),T)):-oneLeg(X,Y),travel(Y,Z,T). 

...但結果還沒有應用：

?- travel(valmont, losAngeles, X). 
X = go(oneLeg(valmont, saarbruecken), go(oneLeg(saarbruecken, paris), go(oneLeg(paris, losAngeles)))) ; 
X = go(oneLeg(valmont, metz), go(oneLeg(metz, paris), go(oneLeg(paris, losAngeles)))) ; 
false. 

我該如何強制更換結果中第oneLeg個實例e具體的byCar,byTrain或byPlane那「證明」oneLeg實例？

Answer 1

firstACommentOnNamingThingsasInJavaByMixingTheCasesWhichIsHardToRead：you_may_find_even_long_names_very_readable_when_using_underscores。

其次，Prolog是一個非常動態語言，你可以很容易地使用call/N家人元謂詞和其他高階謂詞像  (=..)/2構建和調用任意關閉。

在你的榜樣，首先考慮改變謂詞的名字，以適應命名通常的Prolog的慣例，使用強調分隔單詞：

 
by_car(auckland, hamilton). 
by_car(hamilton, raglan). 
by_car(valmont, saarbruecken). 
by_car(valmont, metz). 

by_train(metz, frankfurt). 
by_train(saarbruecken, frankfurt). 
by_train(metz, paris). 
by_train(saarbruecken, paris). 

by_plane(frankfurt, bangkok). 
by_plane(frankfurt, singapore). 
by_plane(paris, los_angeles). 
by_plane(bangkok, auckland). 
by_plane(singapore, auckland). 
by_plane(losAngeles, auckland). 

現在，合適的抽象可能是謂語means/1，這我們可以這樣定義：

 
means(plane). 
means(train). 
means(car). 

這是很容易使用這個動態調用合適的謂詞：

使用此

 
by_means(From, To, Means) :- 
     means(Means), 
     atom_concat(by_, Means, Pred), 
     call(Pred, From, To). 

一種方法看起來是這樣的：

 
route(To, To) --> []. 
route(From, To) --> [Step], 
     { by_means(From, Next, Means), 
      Step =.. [Means,From,Next] }, 
     route(Next, To). 

樣品的查詢和答案：

 
?- phrase(route(valmont, los_angeles), Rs). 
Rs = [car(valmont, saarbruecken), train(saarbruecken, paris), plane(paris, los_angeles)] ; 
Rs = [car(valmont, metz), train(metz, paris), plane(paris, los_angeles)] ; 
false. 

這項工作的關鍵在於手段的系統化的命名約定，書信等方式謂詞。在這種情況下，對應關係是動態構建的，以便一次說明幾個概念。爲了提高效率，靈活性和甚至可能的安全性，您當然也可以通過靜態的Prolog事實對通信本身進行編碼。例如：

 
means_predicate(plane, by_plane). 
means_predicate(train, by_train). 
means_predicate(car, by_car). 

by_means(From, To, Means) :- 
     means_predicate(Means, Pred), 
     call(Pred, From, To). 

Answer 2

如果我必須這樣做，我可能會嘗試將汽車和平面以及火車轉換爲單一表from_to_means。我發現你可以這樣做，如下所示：

forall(byCar(From, To), assertz(from_to_means(From, To, car))) 

然後相同的飛機和火車。在SWI-Prolog的也有短期的擴展，所以也許你可以插入三個原始表

term_expansion(byCar(From, To), from_to_means(From, To, car)). 

與同爲飛機和火車的上方。

然後，您只需評估from_to_means(From, To, Means)或者如果您編寫from_to_means(From, To, train)，則只能選擇一種運輸工具。