clojure：將調試跟蹤添加到名稱空間中的每個函數？

Question

剛開始在我的一個家庭項目中使用log4j，我正準備打開鼠標並將(trace (str "entering: " function-name))剪切粘貼到大型模塊的每個功能中。那麼理智的聲音就被抓住了，並且說「這只是一種更好的方式」......我可以考慮製作一個包裝整個功能塊的宏，並將這些痕跡添加到它們或類似的東西中？來自明智的堆棧溢出clojurians任何意見？

Answer 1

無需宏：

(defn trace-ns 
    "ns should be a namespace object or a symbol." 
    [ns] 
    (doseq [s (keys (ns-interns ns)) 
      :let [v (ns-resolve ns s)] 
      :when (and (ifn? @v) (-> v meta :macro not))] 
    (intern ns 
      (with-meta s {:traced true :untraced @v}) 
      (let [f @v] (fn [& args] 
          (clojure.contrib.trace/trace (str "entering: " s)) 
          (apply f args)))))) 

(defn untrace-ns [ns] 
    (doseq [s (keys (ns-interns ns)) 
      :let [v (ns-resolve ns s)] 
      :when (:traced (meta v))] 
    (alter-meta! (intern ns s (:untraced (meta v))) 
       #(dissoc % :traced :untraced)))) 

...或者類似的東西。最有可能的額外要求是使用filter，以便不在ifn? s上調用trace。 更新：在解決方案中編輯（也處理宏）。更新2：修復了一些重大錯誤。更新4：添加untrace功能。

更新3：這裏有一個例子從我REPL：

user> (ns foo) 
nil 
foo> (defn foo [x] x) 
#'foo/foo 
foo> (defmacro bar [x] x) 
#'foo/bar 
foo> (ns user) 
nil 
user> (trace-ns 'foo) 
nil 
user> (foo/foo :foo) 
TRACE: "entering: foo" 
:foo 
user> (foo/bar :foo) 
:foo 
user> (untrace-ns 'foo) 
nil 
user> (foo/foo :foo) 
:foo