有沒有辦法解析Visual Basic中的位置文件？

Question

我有一個輸入文件包括在位置格式的記錄（前柱First Name是在位置1至10）

像這樣：
John Doe john@example.com

這顯然過於簡化。我真的有超過25列，所以使用Mid是可能的，但過於複雜。我想我可以寫一個能解析它的類，但是我想確保這些不是一個更好的方式，然後再浪費時間。

Answer 1

Microsoft.VisualBasic.FileIO.TextFieldParser類可以解析固定寬度格式。基本用法是創建類的實例，設置屬性以指示格式爲固定寬度，調用指定每列寬度的方法，然後啓動一個循環以一次讀取一條記錄中的數據。這是an example from MSDN。在這個例子中，文件有4列，寬度爲5，寬度爲10，寬度爲11，最後一列的長度是無限的（-1）。

Using Reader As New Microsoft.VisualBasic.FileIO.TextFieldParser("C:\TestFolder\test.log") 
    Reader.TextFieldType = Microsoft.VisualBasic.FileIO.FieldType.FixedWidth 
    Reader.SetFieldWidths(5, 10, 11, -1) 

    Dim currentRow As String() 
    While Not Reader.EndOfData 
    Try 
     currentRow = Reader.ReadFields() 
     Dim currentField As String 
     For Each currentField In currentRow 
     MsgBox(currentField) 
     Next 
    Catch ex As Microsoft.VisualBasic.FileIO.MalformedLineException 
     MsgBox("Line " & ex.Message & "is not valid and will be skipped.") 
    End Try 
    End While 
End Using 

Answer 2

瑞恩的答案比你想要的更合適（不知道這個類是否存在）。

但是，因爲我已經寫的這個C＃版本我想我會繼續在這裏這個貼，因爲它可能會派上用場，爲他人在未來

---

基本上，創建一些委託來處理實際每列的動作。然後只需循環線路併爲每個部分使用Substring。正如在評論中指出的那樣，Substring不是非常優化的，但是，很容易就可以做到這一點，並改變列的實際讀取方式。

VB.NET版本

Public Class Person 

    Public Property FirstName As String 
    Public Property LastName As String 
    Public Property Email As String 

End Class 

Public Class ColumnHandler 

    Public Property Process As Action(Of Person, String) 

    Public Property Length As Integer 

    Public Sub New(processAction As Action(Of Person, String), columnLength As Integer) 
     Process = processAction 
     Length = columnLength 
    End Sub 

End Class 

Module Module1 

    Sub Main() 

     Dim columnHandlers() As ColumnHandler = 
      { 
       New ColumnHandler(Sub(p, s) p.FirstName = s, 10), 
       New ColumnHandler(Sub(p, s) p.LastName = s, 10), 
       New ColumnHandler(Sub(p, s) p.Email = s, 16) 
      } 

     Dim fileLines() As String = 
      { 
       "John  Doe  john@example.com", 
       "Ty  Cobb  anon@example.com" 
      } 

     Dim people As New List(Of Person) 

     For Each line As String In fileLines 

      Dim currentPosition As Integer = 0 
      Dim person As New Person() 

      For Each columnHandler As ColumnHandler In columnHandlers 
       columnHandler.Process.Invoke(person, line.Substring(currentPosition, columnHandler.Length).Trim()) 
       currentPosition += columnHandler.Length 
      Next 

      people.Add(person) 

     Next 

     Console.WriteLine(people.Count.ToString()) 
     Console.WriteLine(people(1).LastName) 
     Console.ReadLine() 

    End Sub 

End Module 

C＃版本（因爲我顯然不知道如何讀的問題標籤或標題）

public class Person 
{ 
    public string FirstName { get; set; } 
    public string LastName { get; set; } 
    public string Email { get; set; } 
} 

void Main() 
{ 
    var columnHandlers = new[] 
    { 
     new {Process = new Action<Person, string>((p, s) => p.FirstName = s), Length = 10}, 
     new {Process = new Action<Person, string>((p, s) => p.LastName = s), Length = 10}, 
     new {Process = new Action<Person, string>((p, s) => p.Email = s), Length = 16}, 
    }; 

    //Replace this with a stream or however you were going to get/read the lines 
    var fileLines = new[] 
    { 
     "John  Doe  john@example.com", 
     "Ty  Cobb  anon@example.com", 
    }; 

    var people = new List<Person>(); 

    foreach (var line in fileLines) 
    { 
     var currentPosition = 0; 
     var person = new Person(); 
     foreach (var columnHandler in columnHandlers) 
     { 
      columnHandler.Process(person, line.Substring(currentPosition, columnHandler.Length).Trim()); 
      currentPosition += columnHandler.Length; 
     } 

     people.Add(person); 
    } 

    Console.WriteLine(people.Count.ToString()); 
    Console.WriteLine(people[1].LastName); 
}