如何關閉Delphi中的非模態窗體

Question

這裏已經討論過了，但不是詳細說明。

我在嘗試讓非模態子窗體關閉時遇到了麻煩。我讓它通知父母，但我得到抽象的錯誤和其他例外。我究竟做錯了什麼？父母是否必須釋放非模態形式，或者不要再嘗試通過該變量來訪問它？

主要形式有：

NonModal := NonModalTForm.Create(Self); 
NonModal.Callback := Callback; 
NonModal.Show; 

Procedure TForm.Callback; // called by non-modal form when closing 
begin 
    FreeAndNil(NonModal); // or should this just be NonModal := nil so I don't try to access a dangling pointer? 
end; 

在NonModal.pas

procedure NonModalTForm.FormClose; 
begin 
    Callback; // calls parent 
end; 

Answer 1

使用隱藏，如果你想顯示窗口以後。

如果要關閉它，請使用Close。 （關閉主窗口，關閉應用程序）。 關閉的確切操作取決於表單參數。

看近距離的來源：

procedure TCustomForm.Close; 
var 
    CloseAction: TCloseAction; 
begin 
    if fsModal in FFormState then 
    ModalResult := mrCancel 
    else 
    if CloseQuery then begin 
     if FormStyle = fsMDIChild then 
     if biMinimize in BorderIcons then 
      CloseAction := caMinimize 
     else 
      CloseAction := caNone 
     else 
     CloseAction := caHide; 
     DoClose(CloseAction); 
     if CloseAction <> caNone then 
     if Application.MainForm = Self then 
      Application.Terminate 
     else if CloseAction = caHide then 
      Hide 
     else if CloseAction = caMinimize then 
      WindowState := wsMinimized 
     else 
      Release; 
    end; 
end; 

但要小心免費。在左邊的窗口隊列中可能會有一些消息會導致崩潰。更好地使用Release來清理窗口。因爲它在釋放它之前等待消息。

Answer 2

你正在做你不應該做的事情。
在NonModalForm的onClose事件中，您調用一些直接釋放它的代碼，但它仍然在事件處理程序執行中，因此最終會產生一個無效的自身對象。
這就是爲什麼在表單上使用Release而不是Free的情況。

正如Gamecat指出的那樣，只需簡單地調用Close即可......
VCL的美妙之處在於它非常簡單。

Answer 3

您可以致電close從FormClose事件以外的其他地方關閉窗體。在FormClose情況下，只需設置等於行動，以執行下列操作之一：

• caFree - 處置形式的完全
• caMinimize - 最小化形式
• caHide - 隱藏形式
• caNone - 忽略收盤

例如：

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction); 
begin 
    Action := caFree; 
end; 

Answer 4

當其他組件被釋放時，VCL已經有了一個通知組件的機制。你可以這樣使用它;

type 
    TfrmParent = class(TForm) 
    btnShowChild: TButton; 
    procedure btnShowChildClick(Sender: TObject); 
    private 
    FChild: TfrmChild; 
    public 
    procedure Notification(AComponent: TComponent; Operation: TOperation); override; 
    end; 


procedure TfrmParent.btnShowChildClick(Sender: TObject); 
begin 
    // Check status of child 
    if FChild = nil then 
    begin 
    // Child does not exist, create it 
    FChild:= TfrmChild.Create(Application); 
    FChild.Show; 

    // Ask Child to notify us when it is destroyed 
    FChild.FreeNotification(Self); 
    end 
    else 
    begin 
    // Child already exists 
    FChild.Show; 
    end; 
end; 

procedure TfrmParent.Notification(AComponent: TComponent; 
    Operation: TOperation); 
begin 
    inherited; 

    if (AComponent = FChild) and (Operation = opRemove) then 
    begin 
    // FChild is about to be freed, so set reference to Child to nil 
    FChild:= nil; 
    end; 
end; 

創建子窗體後，使用創建的窗體的FreeNotification方法來註冊自己，當子窗體被破壞收到通知。

要對通知作出反應，請覆蓋通知方法。在那裏，你可以找出哪個組件被銷燬，並將其與記住的子表單引用進行比較。當您收到通知時，只需將對子窗體的引用設置爲零。

在孩子TfrmChild本身，你不必做任何事情，但什麼skamradt寫道：就在參數Actionb設置爲caFree在OnClose事件。

Answer 5

不使用callback

只需撥打FreeAndNil(Self);以釋放是爲表單創建的所有內存資源。

記住這是你的實現代碼創建的自由對象。由Delphi設計的表單設計器創建的對象非常好。