XSL嵌套每個現在的位置問題

Question

第一關你好

好了我的問題，我試圖建立一種開放源碼的購物車，它使用XML存儲和XSL樣式籃下

1，我的XML

<items> 
    <item> 
     <item-name>vlaue</item-name> 
     <item-number>vlaue</item-number> 
     <quantity>vlaue<quantity> 
     <option> 
      <on0>vlaue</on0> 
      <os0>vlaue</os0> 
      <on1>vlaue</on1> 
      <os1>vlaue</os1> 
     </option> 
    </item> 
</items> 

該XML將一個項目中創建2個選項 由於貝寶允許的7個選項theat一個最大將是我上菲格爾 確定我的XSL

<xsl:for-each select="item"> 
    <input type='hidden' name="item_name_{position()}" value="{item-name}"/> 
    <input type='hidden' name="item_number_{position()}" value="{item-description}"/> 
    <input type='hidden' name="amount_{position()}" value="{unit-price}"/> 
    <input type='hidden' name="quantity_{position()}" value="{@quantity}"/> 
    <xsl:for-each select="option">    
     <input type='hidden' name="on{position()}_(i need this to be item postion)" value="(i need this to be "on" with the option postion appened ie "on0")"/> 
     <input type='hidden' name="os{position()}_{i need this to be item postion}" value="(i need this to be "os" with the option postion appened ie "os0")"/> 
    </xsl:for-each> 
</xsl:for-each> 

所以我真的要問我能有現在的位置的值從外每個傳遞到內每個

如果任何人能幫助它會graet

預先感謝您

Tim Dodgson

Answer 1

我不是100％確定我完全理解XSLT是如何與您發佈的XML相關的。我認爲這將是有意義的編輯你的問題，所以你明確指出：

• 什麼是輸入XML
• 什麼是所需的輸出XML
• 什麼是你與
掙扎XSLT

（也許我應該問這個的評論，但目前已收集足夠的學分這麼做）

回答您的基本問題（從我的困惑抽象）：你總是可以p通過變量分析這些位置信息。只需將外部for-each中的上下文項的位置分配給變量，然後在inner for-each中引用此變量。據我瞭解你的XSLT樣式表，我假設你正在尋找的東西是這樣的：

<xsl:for-each select="item"> 
    <xsl:variable name="itemPos" select="position()"/> 
    <input type='hidden' name="item_name_{position()}" value="{item-name}"/> 
    <input type='hidden' name="item_number_{position()}" value="{item-description}"/> 
    <input type='hidden' name="amount_{position()}" value="{unit-price}"/> 
    <input type='hidden' name="quantity_{position()}" value="{@quantity}"/> 
    <xsl:for-each select="option/*">    
     <input type='hidden' name="{name()}_{$itemPos}" value="{.}"/> 
    </xsl:for-each> 
</xsl:for-each> 

上下文項中的for-each被存儲在一個變量$ itemPos外的位置，它可以是進一步參考。

親切的問候，

羅恩

Answer 2

說實話，我會重新考慮你的XML的設計;通常不建議將數字索引作爲標記名稱的一部分，因爲這使得在xslt或xsd模式中使用起來更加困難。我建議的東西沿着線：

<option> 
     <on index="0">vlaue</on> 
     <os index="0">vlaue</os> 
     <on index="1">vlaue</on> 
     <os index="1">vlaue</os> 
    </option> 

然後，你可以簡單地採取從@index屬性的位置，你也可以做<foreach select="os">只有通過所有的os元素迭代，例如。

Answer 3

你的問題不太清楚，但我認爲你需要像這樣的樣式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="items"> 
     <form> 
      <xsl:apply-templates/> 
     </form> 
    </xsl:template> 
    <xsl:template match="item|option" priority="1"> 
     <xsl:param name="pos" select="position()"/> 
     <xsl:apply-templates select="*"> 
      <xsl:with-param name="pos" select="$pos"/> 
     </xsl:apply-templates> 
    </xsl:template> 
    <xsl:template match="item/*|option/*"> 
     <xsl:param name="pos"/> 
     <input type='hidden' name="{name()}_{$pos}" value="{.}"/> 
    </xsl:template> 
</xsl:stylesheet> 

有了這個正確的輸入：

<items> 
    <item> 
     <item-name>vlaue</item-name> 
     <item-number>vlaue</item-number> 
     <quantity>vlaue</quantity> 
     <option> 
      <on0>vlaue</on0> 
      <os0>vlaue</os0> 
      <on1>vlaue</on1> 
      <os1>vlaue</os1> 
     </option> 
    </item> 
</items> 

輸出：

<form> 
    <input type="hidden" name="item-name_1" value="vlaue" /> 
    <input type="hidden" name="item-number_1" value="vlaue" /> 
    <input type="hidden" name="quantity_1" value="vlaue" /> 
    <input type="hidden" name="on0_1" value="vlaue" /> 
    <input type="hidden" name="os0_1" value="vlaue" /> 
    <input type="hidden" name="on1_1" value="vlaue" /> 
    <input type="hidden" name="os1_1" value="vlaue" /> 
</form> 

注：模式匹配允許重用。 @priority用於解決item/*和option衝突而不依賴錯誤恢復。添加虛擬的form用於良好的輸出（它不是完全需要完整的樣式表）