德爾福2009年 - 在自定義德爾福組件中設置默認屬性值

Question

這應該是非常簡單的，但我找不到我想要的確切答案。我有一個基於TSpeedButton的自定義delphi控件。我希望SpeedButton的Caption屬性始終爲'Comments'，但我不想在運行時設置它，我想將它設置在組件本身中，以便當我將它放在我的表單上時它已經填充了這個文本。我也想設置按鈕的高度和寬度，但我想象這樣做的方法將與設置標題相同。

爲了完整起見，這裏是組件代碼：

unit CustomSpeedButton; 

interface 

uses 
    SysUtils, Classes, Controls, Buttons; 

type 
    TCustomSpeedButton = class(TSpeedButton) 
    private 
    FCommentText: string; 
    FCommentTitle: string; 

    procedure SetCommentText(const Value: string); 
    procedure SetCommentTitle(const Value: string); 

    { Private declarations } 
    protected 
    { Protected declarations } 
    public 
    { Public declarations } 

    published 
    { Published declarations } 
    property CommentTitle: string read FCommentTitle write SetCommentTitle; 
    property CommentText: string read FCommentText write SetCommentText; 
    end; 

procedure Register; 

implementation 

procedure Register; 
begin 
    RegisterComponents('Standard', [TCustomSpeedButton]); 
end; 

{ TCustomSpeedButton } 

procedure TCustomSpeedButton.SetCommentText(const Value: string); 
begin 
    FCommentText := Value; 
end; 

procedure TCustomSpeedButton.SetCommentTitle(const Value: string); 
begin 
    FCommentTitle := Value; 
end; 

end. 

Answer 1

既然你想正確完成標題屬性，梅森的答案不會工作，因爲他錯過了'csSetCaption'的事情，他的'默認'的建議不會工作，因爲標題和你的屬性都是字符串類型。

下面是你想要的單位。

的行爲如下：

1. intially Caption屬性的值將是「評論」
2. 用戶可以覆蓋在設計時通過設置新的值

（如果你不想要2.，那麼你需要像Ken提到的那樣用一個被覆蓋的Loaded方法來指定Caption屬性;但是，從你的問題中不清楚你是否需要這個方法，如果你願意的話，請重新說明你的問題。

這是代碼的工作原理。

對於字符串屬性，您不能提示任何默認的流式系統。 但是，您可以在構造函數中爲設計時間設置初始值：Caption：= DefaultCustomSpeedButtonCaption;

對於Caption屬性，您還必須禁用Caption屬性的默認分配（否則您的組件將自動獲得像'CustomSpeedButton1'這樣的標題）。 這一行代碼適用於您：ControlStyle：= ControlStyle - [csSetCaption];

最後，將組件註冊拆分爲單獨的單元是一種很好的做法。 這使您可以擁有一個設計時包，它可以在IDE中註冊組件，並提供運行時包（或根本沒有包），以便在應用程序中使用組件。

如果您有一個組件圖標，那麼您也將其加載到註冊單元中（因爲它只在設計時需要）。

雷Konopka的寫了書面成分一個很好的書，仍然是非常有效的：Developing Custom Delphi 3 Components 和很多優秀的德爾福書，它是絕版的，但你可以order a PDF copy on his site。

我不確定CommentTitle和CommentText屬性是什麼，所以我將它們放在下面的代碼中。

清單1：實際的組件

unit CustomSpeedButtonUnit; 

interface 

uses 
    SysUtils, Classes, Controls, Buttons; 

const 
    DefaultCustomSpeedButtonCaption = 'Comments'; 

type 
    TCustomCustomSpeedButton = class(TSpeedButton) 
    strict private 
    FCommentText: string; 
    FCommentTitle: string; 
    strict protected 
    procedure SetCommentText(const Value: string); virtual; 
    procedure SetCommentTitle(const Value: string); virtual; 
    public 
    constructor Create(AOwner: TComponent); override; 
    destructor Destroy; override; 
    property CommentTitle: string read FCommentTitle write SetCommentTitle; 
    property CommentText: string read FCommentText write SetCommentText; 
    end; 

    TCustomSpeedButton = class(TCustomCustomSpeedButton) 
    published 
// note you cannot use 'default' for string types; 'default' is only valid for ordinal ordinal, pointer or small set type 
// [DCC Error] CustomSpeedButtonUnit.pas(29): E2146 Default values must be of ordinal, pointer or small set type 
// property Caption default DefaultCustomSpeedButtonCaption; 
    property CommentTitle; 
    property CommentText; 
    end; 

implementation 

constructor TCustomCustomSpeedButton.Create(AOwner: TComponent); 
begin 
    inherited Create(AOwner); 
    Caption := DefaultCustomSpeedButtonCaption; 
    ControlStyle := ControlStyle - [csSetCaption]; 
end; 

destructor TCustomCustomSpeedButton.Destroy; 
begin 
    inherited Destroy; 
end; 

procedure TCustomCustomSpeedButton.SetCommentText(const Value: string); 
begin 
    FCommentText := Value; 
end; 

procedure TCustomCustomSpeedButton.SetCommentTitle(const Value: string); 
begin 
    FCommentTitle := Value; 
end; 

end. 

清單2：組件註冊

unit CustomSpeedButtonRegistrationUnit; 

interface 

procedure Register; 

implementation 

uses 
    CustomSpeedButtonUnit; 

procedure Register; 
begin 
    RegisterComponents('Standard', [TCustomSpeedButton]); 
end; 

end. 

Answer 2

你需要在組件的構造函數來設置初始值。

編輯：你也想把ControlStyle := ControlStyle - [csSetCaption];加到構造函數中。

Answer 3

@Etherman：如果你想有默認值的字符串屬性，你想將它保存到DFM - 即使它是空白的 - 你必須自己做。幸運的是，Delphi爲您提供了方法。看看下面的代碼：

type 
    TMyComp = class(TControl) 
    private 
    FMyStringProperty: string; 
    procedure WriteMyStringProperty(Writer: TWriter); 
    procedure DefineProperties(Filer: TFiler); override; 
    public 
    constructor Create(AOwner: TComponent); override; 
    published 
    property MyStringProperty: string read FMyStringProperty write FMyStringProperty stored False; 
    end; 


implementation 


constructor TMyComp.Create(AOwner: TComponent); 
begin 
    inherited Create(AOwner); 
    FMyStringProperty := 'my default value'; 
end; 

procedure TMyComp.WriteMyStringProperty(Writer: TWriter); 
begin 
    Writer.WriteString(FMyStringProperty); 
end; 

procedure TMyComp.DefineProperties(Filer: TFiler); 
begin 
    inherited DefineProperties(Filer); 
    Filer.DefineProperty('MyStringProperty', nil, WriteMyStringProperty, True); 
end;