Grails域類的屬性攔截

Question

我想攔截對域類屬性的調用來實現訪問控制。

我的第一次嘗試是重寫setProperty和getProperty。通過這樣做，我禁用Grails領域類的所有好的功能，如

domainClass.properties = params 

和數據類型的自動轉換。

接下來的嘗試是使用DelegatingMetaClass，它使我至少能夠打印出實際調用周圍的一些漂亮的日誌消息。但我無法弄清楚如何訪問實際的對象來評估權限。

最後，groovy.lang.Interceptor似乎是一個不錯的選擇，因爲我可以訪問實際的對象。但這是正確的方式嗎？我如何能夠強制攔截所有域類？

非常感謝。

的問候，丹尼爾

Answer 1

只要你引用真正的版本，您可以覆蓋的getProperty和setProperty。加入這樣的代碼來引導對添加攔截所有域類：

class BootStrap { 

    def grailsApplication 

    def init = { servletContext -> 

     for (dc in grailsApplication.domainClasses) { 
     dc.class.metaClass.getProperty = { String name -> 
      // do stuff before access 
      def result 
      def metaProperty = delegate.class.metaClass.getMetaProperty(name) 
      if (metaProperty) { 
       result = metaProperty.getProperty(delegate) 
      } 
      else { 
       throw new MissingPropertyException(name, delegate.class) 
      } 
      // do stuff after access 
      result 
     } 

     dc.class.metaClass.setProperty = { String name, value -> 
      // do stuff before update 
      def metaProperty = delegate.class.metaClass.getMetaProperty(name) 
      if (metaProperty) { 
       metaProperty.setProperty(delegate, value) 
      } 
      else { 
       throw new MissingPropertyException(name, delegate.class) 
      } 
      // do stuff after update 
     } 
     } 
    } 

    def destroy = {} 
}