excel - 使用索引匹配從多個列和行中查找結果

Question

我想使用excel索引匹配功能通過搜索多個列和行來查找結果。

我有以下表設置：

Depot Manger  Employee Employee 
1  Dave  Haris  Alex 
2  Linda  Elliot  Tom 
3  Eric  Michael  Lucy 
4  James  Glenda  Mark 
5  Frank  John  Paul 

我想要得到的庫數量的相關員工或經理，經理姓名或員工姓名在我的手機AE16的值相匹配。

所以我們可以說I型員工亞歷克斯到我的手機AE16則包含我的公式我的手機應該回來與車廠1

目前我使用下列但它只能搜索一列沒有多列。有人可以告訴我怎麼做到這一點？提前致謝。

=INDEX('Depot Data'!A4:A509,MATCH(AE16,'Depot Data'!B4:BH1644,0)) 

Answer 1

的傳統方法：

=INDEX('Depot Data'!$A$4:$A$10, 
IFERROR(MATCH(AE16,'Depot Data'!$B$4:$B$10,0), 
IFERROR(MATCH(AE16,'Depot Data'!$C$4:$C$10,0),MATCH(AE16,'Depot Data'!$D$4:$D$10,0)))) 

我有隻到第10行，但這個你應該能夠很容易地糾正。

或者用數組公式：

{=INDEX('Depot Data'!$A$4:$A$10, 
MIN(IF('Depot Data'!$B$4:$D$10=AE16,ROW('Depot Data'!$B$4:$D$10)-3,11-3)))} 

你知道，如何處理這樣的數組公式？

如果-3部分未在第4行開始，則必須將其更改爲（[firstRow] -1），並且11-3部分必須更改爲[lastRow] +1 - （[firstRow] -1）。

如何從註釋中提到的XOR LX中，下面的數組公式會更靈活，因爲如果在'倉庫數據'中插入或刪除行，則起始和長度部分會自動更改！Row1：10。但對於初學者來說，這當然更加複雜和難以理解。

{=INDEX('Depot Data'!$A$4:$A$10, 
MIN(IF('Depot Data'!$B$4:$D$10=AE16, 
ROW('Depot Data'!$B$4:$D$10)-ROW('Depot Data'!$B$4)+1, 
ROWS('Depot Data'!$B$4:$D$10)+1)))} 

問候

阿克塞爾