Excel VBA - Dictonary.Exists（Dictionary）？

Question

想更好地瞭解如何比較對象類型的鍵。 dicOverall.exists(dic2)返回False而dicOverall.exists(dic1)返回True。我不太確定.Exists比較東西（循環？），但是有無論如何，我可以得到.Exists(dic2)返回True？謝謝！

Sub test() 
    Dim dic1 As Object 
    Dim dic2 As Object 
    Dim dicOverall As Object 


    Set dic1 = CreateObject("scripting.dictionary") 
    Set dic2 = CreateObject("scripting.dictionary") 
    Set dicOverall = CreateObject("scripting.dictionary") 

    dic1("Hi") = 1 
    dic1("Hello") = 1 

    dic2("Hi") = 1 
    dic2("Hello") = 1 

    dicOverall(dic1) = 1 

    Debug.Print dicOverall.exists(dic2) 


End Sub 

Answer 1

我想，如果你這樣做

dicOverall(dic1) = 1 

然後在dicOverall現有的唯一關鍵是對象dic1，你問，如果存在dicOverall關鍵dic2？這個答案不能是true它總是false。

dic1和dic2是2個完全不同的對象，即使它們包含相同的鍵。 .exists不比較這些對象的內容，它只是看到這些對象是不同的對象。

例子：
比方說.exists檢查是否有具體的目標是在一個盒子裏，你有2個蘋果稱爲dic1和dic2。如果你把蘋果dic1放入盒子，並檢查.exists如果蘋果dic2是在框中，你會得到一個沒有。 .exists不檢查是否有和蘋果在框中檢查是否有具體蘋果名爲dic2是在框中。即使它們都是蘋果，看起來也一樣。

Sub AppleExample() 
    Dim apple1 As Object 
    Dim apple2 As Object 
    Dim box As Object 

    Set apple1 = CreateObject("scripting.dictionary") 
    Set apple2 = CreateObject("scripting.dictionary") 
    Set box = CreateObject("scripting.dictionary") 

    'apple1 has 1 stem and a red color 
    apple1("stem") = 1 
    apple1("redColor") = 1 

    'apple2 has 1 stem and a red color 
    apple2("stem") = 1 
    apple2("redColor") = 1 

    'put apple1 into the box 
    box(apple1) = 1 

    'check if apple2 is in the box 
    Debug.Print box.exists(apple2) 
End Sub 

如果你想檢查是否有東西在盒子，看起來像apple1但實際上是apple2那麼你必須檢查所有屬性（幹，顏色，...）自己。

---

如果你想檢查是否dic1具有相同的密鑰爲dic2，那麼你必須檢查...

1. 如果dic1和dic2具有鍵（必要的相同的計數，如果dic2具有從所有鍵dic1但加上其他密鑰！）
2. 如果第一個是真的，然後遍歷所有密鑰dic1並檢查每個單個密鑰是否存在dic2。

下面是關於字典一個很好的資源：VBA Dictionary和Using the Dictionary Class in VBA

Answer 2

我能想到的唯一辦法讓.Exists(dic2)返回True是設置dic2指dic1 - 所以在引擎蓋dic1和dic2只是指向相同的基礎對象。

然後 - 即使你永遠不會做dicOverall.Add dic2, 1如果你做dicOverall.Exists(dic2)，你仍然會得到True。

這完全是缺乏現實生活中的應用程序 - 但如果你正在玩字典的話很有用。在這個示例代碼中，您將看到使用Set dic2 = dic1使它們指向相同的底層字典。而改變dic2的值也會改變它在dic1--顯示它們是指向同一事物的指針。

那麼對於dic2檢查所的dicOverall一鍵返回True：

Option Explicit 

Sub Test() 

    Dim dic1 As New Dictionary 
    Dim dic2 As New Dictionary 
    Dim dicOverall As New Dictionary 

    'add items to first dictionary 
    dic1.Add "foo", "bar" 
    dic1.Add "baz", "qux" 
    'make second refer to first 
    Set dic2 = dic1 
    'add first dictionary to overall 
    dicOverall.Add dic1, 1 

    'change a value in 2nd dictionary and see 1st dictionary change too 
    Debug.Print dic1.Item("baz") 
    dic2.Item("baz") = "hello world" 
    Debug.Print dic1.Item("baz") 

    'shows 1 for both dictionaries 
    '*even though you never added dic2 to dicOverall* 
    Debug.Print dicOverall.Exists(dic1) 
    Debug.Print dicOverall.Exists(dic2) 

End Sub 

我調試輸出：

qux 
hello world 
True 
True