打開Windows資源管理器的目錄，選擇（在Delphi）的特定文件

Question

我有一個程序在Windows資源管理器中打開一個文件夾被傳遞的目錄路徑：

procedure TfrmAbout.ShowFolder(strFolder: string); 
begin 
    ShellExecute(Application.Handle,PChar('explore'),PChar(strFolder),nil,nil,SW_SHOWNORMAL); 
end; 

有沒有辦法也通過這一個文件名（無論是完整的文件名路徑，或只是名稱+擴展名），並在Windows資源管理器中打開文件夾，但也被突出顯示/選擇？我要去的位置有很多文件，我需要在Windows中操作該文件。

Answer 1

是的，你可以使用/select flag當你調用explorer.exe：

ShellExecute(0, nil, 'explorer.exe', '/select,C:\WINDOWS\explorer.exe', nil, 
    SW_SHOWNORMAL) 

一個稍微更看中的（或許也是更可靠）的方法（uses ShellAPI, ShlObj）：

const 
    OFASI_EDIT = $0001; 
    OFASI_OPENDESKTOP = $0002; 

{$IFDEF UNICODE} 
function ILCreateFromPath(pszPath: PChar): PItemIDList stdcall; external shell32 
    name 'ILCreateFromPathW'; 
{$ELSE} 
function ILCreateFromPath(pszPath: PChar): PItemIDList stdcall; external shell32 
    name 'ILCreateFromPathA'; 
{$ENDIF} 
procedure ILFree(pidl: PItemIDList) stdcall; external shell32; 
function SHOpenFolderAndSelectItems(pidlFolder: PItemIDList; cidl: Cardinal; 
    apidl: pointer; dwFlags: DWORD): HRESULT; stdcall; external shell32; 

function OpenFolderAndSelectFile(const FileName: string): boolean; 
var 
    IIDL: PItemIDList; 
begin 
    result := false; 
    IIDL := ILCreateFromPath(PChar(FileName)); 
    if IIDL <> nil then 
    try 
     result := SHOpenFolderAndSelectItems(IIDL, 0, nil, 0) = S_OK; 
    finally 
     ILFree(IIDL); 
    end; 
end;