是`const`字符串參數（線程）安全

Question

此代碼

procedure MyThreadTestA(const AStr: string); 

快於

procedure MyThreadTestB(AStr: string); 

雖然做同樣的工作，無論是傳遞一個指針。

但是，版本B'正確'更新AStr的引用計數，並且如果我更改它，則創建一個副本。
版本A只傳遞一個指針，只有編譯器阻止我更改AStr。

版本A是不是安全的，如果我做的骯髒把戲在彙編或以其他方式規避編譯器的保護，這是衆所周知的，但...

傳遞AStr通過引用作爲const參數線程安全的？
如果AStr的某個其他線程的引用計數變爲零並且該字符串被銷燬，會發生什麼情況？

Answer 1

不，這些技巧不是線程安全的。 Const阻止了add-ref，所以由另一個線程所做的更改將以不可預知的方式影響該值。示例程序，嘗試在P定義改變const：

{$apptype console} 
uses SysUtils, Classes, SyncObjs; 

type 
    TObj = class 
    public 
    S: string; 
    end; 

    TWorker = class(TThread) 
    public 
    procedure Execute; override; 
    end; 

var 
    lock: TCriticalSection; 
    obj: TObj; 

procedure P(const x: string); 
// procedure P(x: string); 
begin 
    Writeln('P(1): x = ', x); 
    Writeln('Releasing obj'); 
    lock.Release; 
    Sleep(10); // give worker a chance to run 
    Writeln('P(2): x = ', x); 
end; 

procedure TWorker.Execute; 
begin 
    // wait until TMonitor is freed up 
    Writeln('Worker started...'); 
    lock.Acquire; 
    Writeln('worker fiddling with obj.S'); 
    obj.S := 'bar'; 
    TMonitor.Exit(obj); 
end; 

procedure Go; 
begin 
    lock := TCriticalSection.Create; 
    obj := TObj.Create; 
    obj.S := 'foo'; 
    UniqueString(obj.S); 
    lock.Acquire; 
    TWorker.Create(False); 
    Sleep(10); // give worker a chance to run and block 
    P(obj.S); 
end; 

begin 
    Go; 
end. 

但它並不僅僅限於線程;修改的基本變量的位置也有類似的效果：

{$apptype console} 
uses SysUtils, Classes, SyncObjs; 

type 
    TObj = class 
    public 
    S: string; 
    end; 

var 
    obj: TObj; 

procedure P(const x: string); 
begin 
    Writeln('P(1): x = ', x); 
    obj.S := 'bar'; 
    Writeln('P(2): x = ', x); 
end; 

procedure Go; 
begin 
    obj := TObj.Create; 
    obj.S := 'foo'; 
    UniqueString(obj.S); 
    P(obj.S); 
end; 

begin 
    Go; 
end. 

Answer 2

要添加到巴里的回答是：這絕對是線程安全的，如果是得到了傳遞的字符串從呼叫者範圍內的局部變量來了。

在這種情況下，如果您的調用返回，那麼局部變量將保存有效的引用，並且唯一的方法（假設只是有效的pascal代碼，不會在asm中擺弄）才能更改該局部變量。

這還包括字符串變量的來源是函數調用的結果（包括屬性訪問，例如TStrings.Strings []）的所有情況，因爲在這種情況下，編譯器必須將字符串存儲在本地temp變量。

線程安全問題只有在您的調用返回之前直接從可以更改該字符串的位置（通過同一個或另一個線程）傳遞字符串時纔會導致線程安全問題。