Excel VBA - 如果單元格是一個整數，刪除整個行

Question

我一直在嘗試使用一些片段來說明如何刪除Excel VBA上的整個行，但我無法修改它們以包含「IsNumber」驗證。

我需要能夠選擇一個活動區域，如：

Set r = ActiveSheet.Range("A1:C10") 

而且因爲它一行之後經過行（和檢查區的每一個細胞），刪除整個行，如果有一個單元格上的數字。

例如：

NA NA NA 21 
NA 22 NA 44 
00 NA NA NA 
NA NA NA NA 
55 NA NA NA 

然後宏將刪除所有的行，除了第四其一是

NA NA NA NA 

Answer 1

隨你挑:)

WAY 1（試驗和測試）

這使用SpecialCells來識別有數字的行。

Sub Sample() 
    Dim ws As Worksheet 
    Dim rng As Range 

    On Error GoTo Whoa 

    Set ws = Sheets("Sheet1") 

    With ws 
     Set rng = .Cells.SpecialCells(xlCellTypeConstants, xlNumbers).EntireRow 

     rng.ClearContents '<~~ or rng.Clear if cells have formatting 

     .Cells.Sort Key1:=.Range("A1") 
    End With 

    Exit Sub 
Whoa: 
    MsgBox Err.Description 
End Sub 

WAY 2（試驗和測試）

這使用循環和Count()檢查數字

Sub Sample() 
    Dim ws As Worksheet 
    Dim delrange As Range 
    Dim lRow As Long, i As Long 

    On Error GoTo Whoa 

    Set ws = Sheets("Sheet1") 

    With ws 
     lRow = .Range("A" & .Rows.Count).End(xlUp).Row 

     For i = 1 To lRow 
      If Application.WorksheetFunction.Count(.Rows(i)) > 0 Then 
       If delrange Is Nothing Then 
        Set delrange = .Rows(i) 
       Else 
        Set delrange = Union(delrange, .Rows(i)) 
       End If 
      End If 
     Next i 

     If Not delrange Is Nothing Then delrange.Delete 
    End With 

    Exit Sub 
Whoa: 
    MsgBox Err.Description 
End Sub 

路3（試驗和測試）

這使用自動過濾器。我假設行1有標題，並且在您的範圍內沒有空白單元格。

Sub Sample() 
    Dim ws As Worksheet 
    Dim lRow As Long, lCol As Long, i As Long 
    Dim ColN As String 

    On Error GoTo Whoa 

    Set ws = Sheets("Sheet1") 

    With ws 
     lRow = .Range("A" & .Rows.Count).End(xlUp).Row 
     lCol = .Cells(1, .Columns.Count).End(xlToLeft).Column 

     For i = 1 To lCol 
      '~~> Remove any filters 
      .AutoFilterMode = False 
      ColN = Split(.Cells(, i).Address, "$")(1) 

      '~~> Filter, offset(to exclude headers) and delete visible rows 
      With .Range(ColN & "1:" & ColN & lRow) 

       .AutoFilter Field:=1, Criteria1:=">=" & _ 
       Application.WorksheetFunction.Min(ws.Columns(i)), _ 
       Operator:=xlOr, Criteria2:="<=" & _ 
       Application.WorksheetFunction.Max(ws.Columns(i)) 

       .Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow.Delete 
      End With 

      '~~> Remove any filters 
      .AutoFilterMode = False 
     Next 
    End With 

    Exit Sub 
Whoa: 
    MsgBox Err.Description 
End Sub 

Answer 2

Dim currentPos As Integer 

currentPos = 1 

Do While (currentPos < yourNumberofRow) 
If (Range("A" & currentPos).Value.IsNumeric = True) Then 
    Rows(currentPos & ":" & currentPos).Select 
    Selection.Delete 
End If 

currentPos = currentPos +1 
Loop 

不嘗試，但容易代碼來了解刪除和則IsNumeric測試。

Answer 3

Sub DeleteNumeric() 

    Dim i As Long 
    Dim rCell As Range 
    Dim rRow As Range 
    Dim rRng As Range 

    'identify the range to search 
    Set rRng = Sheet1.Range("A1:D5") 

    'loop backwards when deleting rows 
    For i = rRng.Rows.Count To 1 Step -1 
     'loop through all the cells in the row 
     For Each rCell In rRng.Rows(i).Cells 
      If IsNumeric(rCell.Value) Then 
       'delete the row and go to the next one 
       rCell.EntireRow.Delete 
       Exit For 
      End If 
     Next rCell 
    Next i 

End Sub