多維數組中的多個字符串vbscript

Question

我想將多個字符串添加到VBScript中的多維數組中。我希望我可以用簡短的方式解釋它： 每個字符串都包含一些用逗號分隔的數據。現在我想將所有這些數據添加到數組中，每個字符串都有一個維度。

例如

Dates = "12.02.2016, 13.08.2017, 19.05.2018" 
Temperatures = "23.1, 24.9, 75.3" 
Humidity = "26, 29, 95" 

這是沒有問題的，通過使用

AmbientConditionsArray = Split(Dates, ", ") 

讓每一個字符串轉換成一個維數組，但我真的不知道把它變成一個二維數組一樣

AmbientConditionsArray(0,0) = Date1 
AmbientConditionsArray(0,1) = Temperature1 
AmbientConditionsArray(0,2) = Humidity1 
AmbientConditionsArray(1,0) = Date2 
AmbientConditionsArray(1,1) = Temperature2 
AmbientConditionsArray(1,2) = Humidity2 

等等。

Answer 1

雖然您可以使用多維數組，但它會比較麻煩。

如何簡單地使用三個獨立的常規數組？

Dates = Split("12.02.2016, 13.08.2017, 19.05.2018", ", ") 
Temperatures = Split("23.1, 24.9, 75.3", ", ") 
Humidity = Split("26, 29, 95", ", ") 

與他們一起作爲一個值塊我會用字典。

Dim AmbientConditions 
Set AmbientConditions = CreateObject("Scripting.Dictionary") 

AmbientConditions.Add "Dates", Split("12.02.2016, 13.08.2017, 19.05.2018", ", ") 
AmbientConditions.Add "Temperatures", Split("23.1, 24.9, 75.3", ", ") 
AmbientConditions.Add "Humidity", Split("26, 29, 95", ", ") 

之後，您可以以可讀的方式訪問單個值：

MsgBox AmbientConditions("Humidity")(1) 
' -> shows "29" 

Answer 2

以形成在這裏你的代碼是什麼可以做;這是一個真正的多維數組。 [代碼被編輯因爲對我而言稍有疏忽]

Dates = Split("12.02.2016, 13.08.2017, 19.05.2018", ", ") 
Temperatures = Split("23.1, 24.9, 75.3", ", ") 
Humidity = Split("26, 29, 95", ", ") 

Dim AmbientConditionsArray() 
ReDim AmbientConditionsArray(2,UBound(Dates)) 
For i = 0 TO UBound(Dates) 
    AmbientConditionsArray(0,I) = Dates(I) 
    AmbientConditionsArray(0,I) = Temperatures(I) 
    AmbientConditionsArray(0,I) = Humidity(I) 
Next 

現在所有的數據被整齊地存放在一個多維數組。

這第二個模型接近第一個答案，但我認爲它也符合您的陳述需求。 [它使用嵌套數組來滿足混合多維數組的目的]

Dates = Split("12.02.2016, 13.08.2017, 19.05.2018", ", ") 
Temperatures = Split("23.1, 24.9, 75.3", ", ") 
Humidity = Split("26, 29, 95", ", ") 

Dim AmbientConditions 

AmbientConditions = Array(Dates, Temperatures, Humidity) 

For I = 0 To UBound(Dates) 
    Debug.Print AmbientConditions(0)(I), AmbientConditions(1)(I), AmbientConditions(2)(I) 
Next 

Answer 3

@Tomalak'sanswer是這樣做的一個非常簡潔的方式，但如果你確實想要一個本地多維數組的方式接近你原來的要求你使用動態數組，就像這樣。

Option Explicit 

'Named constants for the three dimensions 
Const COND_DATE = 0 
Const COND_TEMPERATURE = 1 
Const COND_HUMIDITY = 2 

Dim Dates, Temperatures, Humidity, i 
Dim AmbientConditions() 

Dates = Split("12.02.2016, 13.08.2017, 19.05.2018", ", ") 
Temperatures = Split("23.1, 24.9, 75.3", ", ") 
Humidity = Split("26, 29, 95", ", ") 

ReDim AmbientConditions(2, UBound(Dates)) 

For i = 0 to Ubound(Dates) 
    AmbientConditions(COND_DATE, i) = Dates(i) 
    AmbientConditions(COND_TEMPERATURE, i) = Temperatures(i) 
    AmbientConditions(COND_HUMIDITY, i) = Humidity(i) 
Next 

For i = 0 To UBound(AmbientConditions, 2) 
    WScript.Echo AmbientConditions(COND_DATE, i) 
    WScript.Echo AmbientConditions(COND_TEMPERATURE, i) 
    WScript.Echo AmbientConditions(COND_HUMIDITY, i) & vbCrLf 
Next 

輸出：

 
12.02.2016 
23.1 
26 

13.08.2017 
24.9 
29 

19.05.2018 
75.3 
95 

也跟着@Tomalak'ssuggestion to use Named Constants爲各種尺寸。