如何從第一階段加載第二階段啓動加載器？

Question

我寫了簡單的第一階段啓動加載程序，它使用中斷向BIOS顯示「Hello world」。現在作爲編寫第二階段的下一個顯而易見的步驟，但是代碼應該存在以及如何從第一階段加載它？

下面是第一階段的程序

[BITS 16] ;Tells the assembler that its a 16 bit code 
[ORG 0x7C00] ;Origin, tell the assembler that where the code will 
       ;be in memory after it is been loaded 

MOV SI, HelloString ;Store string pointer to SI 
CALL PrintString ;Call print string procedure 
JMP $  ;Infinite loop, hang it here. 


PrintCharacter: ;Procedure to print character on screen 
    ;Assume that ASCII value is in register AL 
MOV AH, 0x0E ;Tell BIOS that we need to print one charater on screen. 
MOV BH, 0x00 ;Page no. 
MOV BL, 0x07 ;Text attribute 0x07 is lightgrey font on black background 

INT 0x10 ;Call video interrupt 
RET  ;Return to calling procedure 



PrintString: ;Procedure to print string on screen 
    ;Assume that string starting pointer is in register SI 

next_character: ;Lable to fetch next character from string 
MOV AL, [SI] ;Get a byte from string and store in AL register 
INC SI  ;Increment SI pointer 
OR AL, AL ;Check if value in AL is zero (end of string) 
JZ exit_function ;If end then return 
CALL PrintCharacter ;Else print the character which is in AL register 
JMP next_character ;Fetch next character from string 
exit_function: ;End label 
RET  ;Return from procedure 


;Data 
HelloString db 'Hello World', 0 ;HelloWorld string ending with 0 

TIMES 510 - ($ - $$) db 0 ;Fill the rest of sector with 0 
DW 0xAA55   ;Add boot signature at the end of bootloader 

Answer 1

在x86上，你會做以下（簡化）：

• 有引導程序加載磁盤/軟盤的第n個部門（無論你從哪裏啓動）到內存中並執行它（即加載段/偏移量，並執行retf）。一個更好的選擇是在文件系統中搜索某個文件名（例如KERNEL.BIN） - 但是你需要知道文件系統類型（例如，如果你是從軟盤映像進行測試，則爲FAT12）。
• 內核然後會以實模式啓動。它設置代碼描述符，GDT等等，激活32位尋址（您應該聽說過「A20」）並最終進入保護模式。然後你需要遠程跳轉到一個32位的代碼段（內核文件必須以32位代碼處於絕對位置的方式連接在一起，例如在偏移512處，緊跟在16位實模式之後） 。
• 然後，32位內核程序集僅定義了EXTERN _mykernel並調用該符號。
• 然後，你可以開始編寫你的內核作爲C函數mykernel。

好吧，這是我幾年前做的一個簡短的概述（有很多從互聯網複製&粘貼;）。如果這是沒有幫助的，下面是OS開發一些好的網絡資源：

• http://www.brokenthorn.com/Resources/OSDevIndex.html
• http://wiki.osdev.org/Main_Page
• http://lowlevel.brainsware.org/wiki/index.php/Hauptseite（維基許多愛好者OS開發商中，只有德國...）

希望幫助^^

Answer 2

看看這裏的GRUB實現（階段1）：

http://src.illumos.org/source/xref/illumos-gate/usr/src/grub/grub-0.97/stage1/stage1.S

首先注意到起始點爲0x7c00，結束簽名爲0xaa55，這是第一個扇區。從拆解中，U可以看到這一點：

349 copy_buffer: 
350 movw ABS(stage2_segment), %es 
351 
352 /* 
353 * We need to save %cx and %si because the startup code in 
354 * stage2 uses them without initializing them. 
355 */ 
356 pusha 
357 pushw %ds 
358 
359 movw $0x100, %cx 
360 movw %bx, %ds 
361 xorw %si, %si 
362 xorw %di, %di 
363 
364 cld 
365 
366 rep 
367 movsw 
368 
369 popw %ds 
370 popa 
371 
372 /* boot stage2 */ 
373 jmp *(stage2_address) 
374 
375 /* END OF MAIN LOOP */ 
376 

本質的邏輯是第2階段代碼複製到內存的另一部分，並且跳躍後，直接出現，那就是「啓動階段2 」。換句話說，「啓動階段1」在將扇區加載到內存後從BIOS中有效觸發，而階段2則是您跳到那裏的地方 - 它可以在任何地方。

Answer 3

加載階段2並跳轉到它

use16 
org 0x7C00 

    ; You should do further initializations here 
    ; like setup the stack and segment registers. 

    ; Load stage 2 to memory. 
    mov ah, 0x02 
    ; Number of sectors to read. 
    mov al, 1 
    ; This may not be necessary as many BIOS set it up as an initial state. 
    mov dl, 0x80 
    ; Cylinder number. 
    mov ch, 0 
    ; Head number. 
    mov dh, 0 
    ; Starting sector number. 2 because 1 was already loaded. 
    mov cl, 2 
    ; Where to load to. 
    mov bx, stage2 
    int 0x13 

    jmp stage2 

    ; Magic bytes.  
    times ((0x200 - 2) - ($ - $$)) db 0x00 
    dw 0xAA55 

stage2: 

    ; Print 'a'. 
    mov ax, 0x0E61 
    int 0x10 

    cli 
    hlt 

    ; Pad image to multiple of 512 bytes. 
    times ((0x400) - ($ - $$)) db 0x00 

編譯並執行最少的可運行NASM BIOS例如：

nasm -f bin -o main.img main.asm 
qemu-system-i386 main.img 

預期結果：a被打印在屏幕上，然後將程序暫停。

測試在Ubuntu 14.04。

使用接頭腳本和更正確的初始化（段寄存器，棧）on my GitHub理智GAS例子。