遞增一個INI文件的節號

Question

我有一個INI文件存儲一些整數的設置。部分名稱爲存儲這樣的：

[ColorScheme_2] 
name=Dark Purple Gradient 
BackgroundColor=224 
BackgroundBottom=2 
BackgroundTop=25 
... 

[ColorScheme_3] 
name=Retro 
BackgroundColor=5 
BackgroundBottom=21 
BackgroundTop=8 
... 

我需要找出一種方法來創建新的部分，即增加從最高的節號配色方案數+1。我有一個列出當前顏色名稱的組合框，所以當用戶保存到INI文件時，現有的方案只會被覆蓋。如何檢查ComboBox文本以查看它是否是現有的部分，如果不是，請使用增加的名稱創建一個新的部分？ （即從上面的示例代碼，ColorScheme_2和ColorScheme_3已經存在，所以下一個要創建的部分將是ColorScheme_4）。

Answer 1

您可以通過使用ReadSections方法閱讀所有部分，然後遍歷返回的字符串列表，並分析每個項目在它存儲的最高尋到指標值：

uses 
    IniFiles; 

function GetMaxSectionIndex(const AFileName: string): Integer; 
var 
    S: string; 
    I: Integer; 
    Index: Integer; 
    IniFile: TIniFile; 
    Sections: TStringList; 
const 
    ColorScheme = 'ColorScheme_'; 
begin 
    Result := 0; 
    IniFile := TIniFile.Create(AFileName); 
    try 
    Sections := TStringList.Create; 
    try 
     IniFile.ReadSections(Sections); 
     for I := 0 to Sections.Count - 1 do 
     begin 
     S := Sections[I]; 
     if Pos(ColorScheme, S) = 1 then 
     begin 
      Delete(S, 1, Length(ColorScheme)); 
      if TryStrToInt(S, Index) then 
      if Index > Result then 
       Result := Index; 
     end; 
     end; 
    finally 
     Sections.Free; 
    end; 
    finally 
    IniFile.Free; 
    end; 
end; 

和使用：

procedure TForm1.Button1Click(Sender: TObject); 
begin 
    ShowMessage(IntToStr(GetMaxSectionIndex('d:\Config.ini'))); 
end; 

Answer 2

如何檢查ComboBox文本以查看它是否爲現有部分，如果不是，請使用增加的名稱創建一個新的部分？

像這樣：

const 
    cPrefix = 'ColorScheme_'; 
var 
    Ini: TIniFile; 
    Sections: TStringList; 
    SectionName: String; 
    I, Number, MaxNumber: Integer; 
begin 
    Ini := TIniFile.Create('myfile.ini') 
    try 
    SectionName := ComboBox1.Text; 
    Sections := TStringList.Create; 
    try 
     Ini.ReadSections(Sections); 
     Sections.CaseSensitive := False; 
     if Sections.IndexOf(SectionName) = -1 then 
     begin 
     MaxNumber := 0; 
     for I := 0 to Sections.Count-1 do 
     begin 
      if StartsText(cPrefix, Sections[I]) then 
      begin 
      if TryStrToInt(Copy(Sections[I], Length(cPrefix)+1, MaxInt), Number) then 
      begin 
       if Number > MaxNumber then 
       MaxNumber := Number; 
      end; 
      end; 
     end; 
     SectionName := Format('%s%d', [cPrefix, MaxNumber+1]); 
     end; 
    finally 
     Sections.Free; 
    end; 
    // use SectionName as needed... 
    finally 
    Ini.Free; 
    end; 
end;