ColdFusion的正則表達式生成蛞蝓

Question

我有這個功能產生蛞蝓在ColdFusion中：

<cffunction name="generateSlug" output="false" returnType="string"> 
    <cfargument name="str"> 
    <cfargument name="spacer" default="-"> 

    <cfset var ret = "" /> 

    <cfset str = lCase(trim(str)) /> 
    <cfset str = reReplace(str, "[àáâãäå]", "a", "all") /> 
    <cfset str = reReplace(str, "[èéêë]", "e", "all") /> 
    <cfset str = reReplace(str, "[ìíîï]", "i", "all") /> 
    <cfset str = reReplace(str, "[òóôö]", "o", "all") /> 
    <cfset str = reReplace(str, "[ùúûü]", "u", "all") /> 
    <cfset str = reReplace(str, "[ñ]", "n", "all") /> 
    <cfset str = reReplace(str, "[^a-z0-9-]", "#spacer#", "all") /> 
    <cfset ret = reReplace(str, "#spacer#+", "#spacer#", "all") /> 

    <cfif left(ret, 1) eq "#spacer#"> 
     <cfset ret = right(ret, len(ret)-1) /> 
    </cfif> 
    <cfif right(ret, 1) eq "#spacer#"> 
     <cfset ret = left(ret, len(ret)-1) /> 
    </cfif> 

    <cfreturn ret /> 
</cffunction> 

，然後我用這稱之爲：

<cfset stringToBeSlugged = "This is a string abcde àáâãäå èéêë ìíîï òóôö ùúûü ñ año ñññññññññññññ" /> 
<cfset slug = generateSlug(stringToBeSlugged) /> 
<cfoutput>#slug#</cfoutput> 

但這是輸出我這個毛坯：

這 - 是 - 一個字符串，ABCDE-aaaaaaeeeeiiiioooouuu - UNA-NO-NNNNNNNNNNNNN

似乎所有的重音字符都被正確地替換了，但是這個函數在替換它們後插入了' - '。爲什麼？

錯誤在哪裏？

PD：我期待這輸出：

this-is-a-string-abcde-aaaaaa-eeee-iiii-oooo-uuuu-n-ano-nnnnnnnnnnnnn 

感謝。

Answer 1

這是否適合您？ （我已經修改了一個我們在內部使用的類似腳本。）我相信我們在ColdFusion 8中使用了它，因爲我們仍然使用它來處理CF9。

<cffunction name="generateSlug" output="false" returnType="string"> 
    <cfargument name="str" default=""> 
    <cfargument name="spacer" default="-"> 
    <cfset var ret = replace(arguments.str,"'", "", "all")> 
    <cfset ret = trim(ReReplaceNoCase(ret, "<[^>]*>", "", "ALL"))> 
    <cfset ret = ReplaceList(ret, "À,Á,Â,Ã,Ä,Å,Æ,È,É,Ê,Ë,Ì,Í,Î,Ï,Ð,Ñ,Ò,Ó,Ô,Õ,Ö,Ø,Ù,Ú,Û,Ü,Ý,à,á,â,ã,ä,å,æ,è,é,ê,ë,ì,í,î,ï,ñ,ò,ó,ô,õ,ö,ø,ù,ú,û,ü,ý,&nbsp;,&amp;", "A,A,A,A,A,A,AE,E,E,E,E,I,I,I,I,D,N,O,O,O,O,O,0,U,U,U,U,Y,a,a,a,a,a,a,ae,e,e,e,e,i,i,i,i,n,o,o,o,o,o,0,u,u,u,u,y, , ")> 
    <cfset ret = trim(rereplace(ret, "[[:punct:]]"," ","all"))> 
    <cfset ret = rereplace(ret, "[[:space:]]+","!","all")> 
    <cfset ret = ReReplace(ret, "[^a-zA-Z0-9!]", "", "ALL")> 
    <cfset ret = trim(rereplace(ret, "!+", arguments.Spacer, "all"))> 
    <cfreturn ret> 
</cffunction> 

<cfset stringToBeSlugged = "This is a string abcde àáâãäå èéêë ìíîï òóôö ùúûü ñ año ñññññññññññññ" /> 
<cfoutput>"#stringToBeSlugged# = #generateSlug(stringToBeSlugged)#</cfoutput> 

支持更多的國際字符

如果你想擴展您的國際字符的支持，你可以使用ICU4J（JAVA）和保羅·黑斯廷斯Transliterator.CFC音譯所有的字符和然後用破折號替換剩餘的空格，破折號，斜線等。

https://gist.github.com/JamoCA/ec4617b066fc4bb601f620bc93bacb57

http://site.icu-project.org/download

同時安裝後，可以通過識別語言ID（轉換爲）將非拉丁字符和傳遞要轉換的字符串：

<cfset Transliterator = CreateObject("component","transliterator")> 

<cfoutput> 
<cfloop array="#TestStrings#" index="TestString"> 
<h3>TestString = "#TestString#"</h3> 
<blockquote> 
    <div>CFC-1 = #Transliterator.transliterate('Latin-ASCII', TestString)#</div> 
    <div>CFC-2 = #Transliterator.transliterate('any-NFD; [:nonspacing mark:] any-remove; any-NFC', TestString)#</div>  
</blockquote> 
<hr> 
</cfloop> 
</cfoutput> 

<h2>Available Language IDs</h2> 
<cfdump var="#Transliterator.getAvailableIDs()#" label="Language IDs">