如何在Delphi XE中將背景圖像設置爲TListview？

Question

我怎麼能在Delphi XE中將背景圖像設置爲TListview？

我想製作一個應用程序，如Windows資源管理器。

Answer 1

爲了在列表視圖中設置水印，您需要使用LVM_SETBKIMAGE消息，並且需要重寫TListView的默認WM_ERASEBKGND消息。列表視圖獲取位圖句柄的所有權，因此您需要使用TBitmap的ReleaseHandle，而不僅僅是Handle。

如果您希望它與左上角對齊，而不是像Explorer那樣右下角，請使用LVBKIF_SOURCE_HBITMAP而不是LVBKIF_TYPE_WATERMARK作爲ulFlags值。

uses 
    CommCtrl, ...; 

type 
    TListView = class(ComCtrls.TListView) 
    protected 
    procedure WndProc(var Message: TMessage); 
     override; 
    end; 

    TForm4 = class(TForm) 
    ListView1: TListView; 
    procedure FormCreate(Sender: TObject); 
    end; 

procedure TListView.WndProc(var Message: TMessage); 
begin 
    if Message.Msg = WM_ERASEBKGND then 
    DefaultHandler(Message) 
    else 
    inherited WndProc(Message); 
end; 

procedure TForm4.FormCreate(Sender: TObject); 
var 
    Img: TImage; 
    BkImg: TLVBKImage; 
begin 
    FillChar(BkImg, SizeOf(BkImg), 0); 
    BkImg.ulFlags := LVBKIF_TYPE_WATERMARK; 
    // Load image and take ownership of the bitmap handle 
    Img := TImage.Create(nil); 
    try 
    Img.Picture.LoadFromFile('C:\Watermark.bmp'); 
    BkImg.hbm := Img.Picture.Bitmap.ReleaseHandle; 
    finally 
    Img.Free; 
    end; 
    // Set the watermark 
    SendMessage(ListView1.Handle, LVM_SETBKIMAGE, 0, LPARAM(@BkImg)); 
end; 

拉伸水印

ListView中本身不支持在整個背景拉伸的位圖。要做到這一點，你需要自己做一個StretchBlt來響應WM_ERASEBKGND。

type 
    TMyListView = class(TListView) 
    protected 
    procedure CreateHandle; override; 
    procedure CreateParams(var Params: TCreateParams); override; 
    procedure WMEraseBkgnd(var Msg: TWMEraseBkgnd); message WM_ERASEBKGND; 
    public 
    Watermark: TBitmap; 
    end; 

procedure TMyListView.CreateHandle; 
begin 
    inherited; 
    // Set text background color to transparent 
    SendMessage(Handle, LVM_SETTEXTBKCOLOR, 0, CLR_NONE); 
end; 

procedure TMyListView.CreateParams(var Params: TCreateParams); 
begin 
    inherited; 
    // Invalidate every time the listview is resized 
    Params.Style := Params.Style or CS_HREDRAW or CS_VREDRAW; 
end; 

procedure TMyListView.WMEraseBkgnd(var Msg: TWMEraseBkgnd); 
begin 
    StretchBlt(Msg.DC, 0, 0, Width, Height, Watermark.Canvas.Handle, 
    0, 0, Watermark.Width, Watermark.Height, SrcCopy); 
    Msg.Result := 1; 
end; 

Answer 2

一個Tlistview是不錯，但如果你想要更多。我建議你必須更新VirtualStringTree(VirtualTreeView)非常靈活，你可以定製它幾乎任何你想要的，最重要的是它的免費。