如何從Perl哈希中刪除空的數組/參考？

Question

可以說我有下面的Perl哈希：

%hash = ( 
    'A' => { 
     'B' => ['C', 'D', 'E'], 
     'F' => { 'G' => [], 'H' => [] }, 
     'I' => [] 
     }); 

，我想擺脫[]的來獲得下面的散列結果：

%hash = ( 
    'A' => [ 
     'B' => ['C', 'D', 'E'], 
     'F' => [ 'G', 'H', 'I' ] 
     ] 
    ) 

（我希望我我的{}和[]平衡，我的道歉，如果沒有，但）基本上我想這樣做，沒有空陣列/裁判存在。我確信這是可能的/簡單的，但我不確定delete()是否可以工作，或者是否有更好的方法或Perl模塊。有人能引導我走向正確的方向嗎？

Answer 1

看起來好像你的數據可能是任意嵌套的，你想遞歸地遍歷它，將某些模式重寫到其他模式。爲此，我會使用Data::Visitor。

use Data::Visitor::Callback; 
use List::MoreUtils 'all'; 

my $visitor = Data::Visitor::Callback->new(
    hash => sub { 
     my ($self, $href) = @_; 

     # fold hashrefs with only empty arrayrefs as values into arrayrefs 
     if (all { ref $_ eq 'ARRAY' && !@{ $_ } } values %{ $href }) { 
      return [ keys %{ $href } ]; 
     } 

     # strip k/v pairs with an empty arrayref as a value 
     return { 
      map { 
       $_ => $href->{$_} 
      } grep { 
       ref $href->{$_} ne 'ARRAY' || @{ $href->{$_} } 
      } keys %{ $href } 
     }; 
    }, 
); 

my %new_hash = %{ $visitor->visit(\%hash) }; 

這只是說明我會使用的基本方法，以及發生在你給的例子輸入工作。它可能需要根據你想在其他評論中指出的角落案例中做什麼進行各種調整。

Answer 2

[這應該是一個評論，但我需要的格式。]

你的問題是令人費解。 （1）I密鑰（來自原始散列）以什麼原理結束於F密鑰的列表中（在預期的散列中）？ （2）如果F包含除了空數組參考之外的東西會發生什麼（請參閱我對原始哈希的補充）？

my %hash_orig = (
    'A' => { 
     'B' => ['C', 'D', 'E'], 
     'F' => { 
      'G' => [], 
      'H' => [], 
      'Z' => ['FOO', 'BAR'], # Not in the OP's original. 
     }, 
     'I' => [], 
    }, 
); 

my %hash_expected = (
    'A' => [ 
     'B' => ['C', 'D', 'E'], 
     'F' => [ 'G', 'H', 'I'], # Where should the Z info go? 
    ], 
); 

Answer 3

散步（樹，無論）是一種技術，任何程序員應該知道。 rafl uses a visitor module，但在某些情況下，我認爲治療幾乎比疾病更糟糕。

您的預期輸出是你的意圖嗎？這與你在文中所說的看起來不同，如FM says。我在我的例子中使用他的散列。

如果您使用隊列，這很容易。你從頂層散列開始。每次遇到散列引用時，都會將其添加到隊列中。當你運行一個數組ref時，你檢查它是否有值，如果沒有，則刪除它。一切你獨自離開：

#!perl 
use strict; 
use warnings; 
use 5.010; 

my %hash = (# From FM 
    'A' => { 
     'B' => ['C', 'D', 'E'], 
     'F' => { 
      'G' => [], 
      'H' => [], 
      'Z' => ['FOO', 'BAR'], # Not in the OP's original. 
     }, 
     'I' => [], 
    }, 
); 

my @queue = (\%hash); 

while(my $ref = shift @queue) { 
    next unless ref $ref eq ref {}; 

    KEY: foreach my $key (keys %$ref) { 
     if(ref $ref->{$key} eq ref {}) { 
      push @queue, $ref->{$key}; 
      next KEY; 
      } 
     elsif(ref $ref->{$key} eq ref []) { 
      delete $ref->{$key} if @{$ref->{$key}} == 0; 
      } 
     } 
    } 

use Data::Dumper; 
print Dumper(\%hash); 

我的輸出是：

$VAR1 = { 
      'A' => { 
        'F' => { 
          'Z' => [ 
            'FOO', 
            'BAR' 
            ] 
          }, 
        'B' => [ 
          'C', 
          'D', 
          'E' 
          ] 
       } 
     }; 

即輸出聽起來更像是你所要求的是什麼，而不是您指定的重組。你能澄清輸出嗎？