檢查字符串是在範圍內的Excel VBA與篩選命令

Question

我試着去檢查，如果單元格區域各有另一範圍內

這是我當前的代碼中定義的值：

Sub CheckInstallationName() 

    Dim LastRow As Long 

    With Worksheets(2) 
     LastRow = .Cells(.Rows.Count, Worksheets(1).Cells(4, 3).Value).End(xlUp).Row 
    End With 

    Dim rngA As Range 
    Set rngA = Range(Worksheets(1).Cells(4, 3).Value & "4:" & Worksheets(1).Cells(4, 3).Value & LastRow) 

    Dim cellA As Range 
    Dim InstallationNameRange As Variant 

    InstallationNameRange = Worksheets(1).Range("B16:B32").Value 

    For Each cellA In rngA 
     If UBound(Filter(InstallationNameRange, cellA.Value)) < 0 Then 
      'Some code 
     End If 
    Next cellA 

End Sub 

在If UBound(filter(InstallationNameRange, cellA.Value)) < 0 Then我收到錯誤「運行時錯誤'13'：類型不匹配」，找不到解決方案。可能它是一個非常小的修復。如果沒有這個if語句代碼工作

Answer 1

打開一個新的Excel和寫：

Public Sub CheckRangeInRange() 

    Dim rngA  As Range 
    Dim rngB  As Range 
    Dim rngCellA As Range 
    Dim rngCellB As Range 
    Dim blnError As Boolean 

    Set rngA = Worksheets(1).Range("A1:B10") 
    Set rngB = Worksheets(1).Range("D10:E20") 

    rngA.Interior.Color = vbYellow 
    rngB.Interior.Color = vbRed 

    For Each rngCellA In rngA 
     blnError = True 
     For Each rngCellB In rngB 
      If rngCellA = rngCellB Then 
       blnError = False 
      End If 
     Next rngCellB 
     If blnError Then Debug.Print "Display Error here!" 
    Next rngCellA 

End Sub 

放一些數值A1:B10和D10:E20和匹配值的地址將在即時窗口打印。

Answer 2

您不能在2-d範圍內使用Filter，並且從Range創建的任何數組都是2-d，即使它是單行或列。

您可以使用'雙Transpose特技`這個question。請注意高票通過的答案，而不是接受的答案。

例如爲：

Option Explicit 

Sub Test() 

    Dim rng As Range 
    Set rng = Sheet2.Range("C20:E20") 'a, b, c 

    ' use the double transpose trick to convert 2-d array to 1-d array 
    Dim arr As Variant 
    arr = Application.WorksheetFunction.Transpose(_ 
     Application.WorksheetFunction.Transpose(rng.Value)) 

    ' now Filter will work 
    Dim out As Variant 
    out = Filter(arr, "a") 

    Debug.Print out(0) 

End Sub