如何以編程方式確定VBA中的Option Base的當前設置

Question

如何以編程方式確定VBA中的Option Base的當前設置？ Option Base可以設置爲0或1，並且這可以確定數組索引是從0還是1開始（請參閱MSDN）。

但是，我看不到任何簡單的方法來找出當前設置是什麼。我希望有可能是一個Option()功能，我可以將參數傳遞，是這樣的：

Debug.Print Option("Base") 

，它會告訴我，但它似乎並不在那裏。

Answer 1

雖然我同意@jonsharpe，如果您使用Lbound(arr)和Ubound(arr)，您不需要在運行時知道這一點，但我認爲這是一個有趣的問題。

首先，正確循環數組的示例。現在

For i = LBound(arr) To Ubound(arr) 
    ' do something 
Next 

---

，爲了做到準確你問什麼，你需要訪問使用VBIDE庫。否則稱爲「Microsoft Visual Basic for Applications擴展性」庫。它提供對IDE和代碼的訪問。您可以使用它來發現是否已聲明Option Base 1。我不建議在運行時嘗試這樣做。這在開發過程中作爲一種靜態代碼分析會更有用。

首先，您需要登錄add a reference to the library和grant the code access to itself。一旦你這樣做了，下面的代碼應該做你想做的。

Public Sub FindOptionBase1Declarations() 

    Dim startLine As Long 
    startLine = 1 

    Dim startCol As Long 
    startCol = 1 

    Dim endLine As Long 
    endLine = 1 ' 1 represents the last line of the module 

    Dim endCol As Long 
    endCol = 1 ' like endLine, 1 designates the last Col 

    Dim module As CodeModule 
    Dim component As VBComponent 
    For Each component In Application.VBE.ActiveVBProject.VBComponents ' substitute with any VBProject you like 
     Set module = component.CodeModule 

     If module.Find("Option Base 1", startLine, startCol, endLine, endCol, WholeWord:=True, MatchCase:=True, PatternSearch:=False) Then 

      Debug.Print "Option Base 1 turned on in module " & component.Name 

      ' variables are passed by ref, so they tell us the exact location of the statement 
      Debug.Print "StartLine: " & startLine 
      Debug.Print "EndLine: " & endLine 
      Debug.Print "StartCol: " & startCol 
      Debug.Print "EndCol: " & endCol 

      ' this also means we have to reset them before we look in the next module 
      startLine = 1 
      startCol = 1 
      endLine = 1 
      endCol = 1 
     End If 

    Next 

End Sub 

查看CodeModule.Find documentation瞭解更多信息。

---

如果使用外接爲Rubberduck有Code Inspection會告訴你整個活動項目的這個所有實例的選項，@ Mat'sMug和我的開源項目。

See this for more information on that particular inspection。

Answer 2

Function GetBaseOption() As Long 

    Dim arr 

    arr = Array("a") 
    GetBaseOption = LBound(arr) 

End Sub