加載XSL代碼的外部塊

Question

是否可以加載類似於加載代碼塊的XSL代碼的外部塊，例如aspx include？ EG：

<xsl:if test="$ShowNextButton='No'"> 
     <!-- A Block of external code would be loaded here --> 
    </xsl:if> 

我使用XSLT 1.0，如果有差別。

Answer 1

如果您的「外部XSL代碼」塊可以放在命名模板中，您可以輕鬆完成此操作。

下面是一個使用主XSLT樣式表（base.xsl）幷包含外部XSLT樣式表（include.xsl）的通用示例。

input.xml中

<test> 
    <foo trigger-template="yes"> 
    <bar>Original "bar".</bar> 
    </foo> 
    <foo trigger-template="no"> 
    <bar>Original "bar".</bar> 
    </foo> 
</test> 

base.xsl

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:include href="include.xsl"/> 
    <xsl:output indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="foo"> 
    <foo> 
     <xsl:if test="@trigger-template='yes'"> 
     <xsl:call-template name="external-template"> 
      <xsl:with-param name="statement" select="'Successfully called external XSL code!'"/> 
     </xsl:call-template> 
     </xsl:if> 
     <xsl:apply-templates/> 
    </foo> 
    </xsl:template> 

</xsl:stylesheet> 

include.xsl

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:template name="external-template"> 
    <xsl:param name="statement"/> 
    <bar><xsl:value-of select="$statement"/></bar> 
    </xsl:template> 

</xsl:stylesheet> 

output.xml

<test> 
    <foo> 
     <bar>Successfully called external XSL code!</bar> 
     <bar>Original "bar".</bar> 
    </foo> 
    <foo> 
     <bar>Original "bar".</bar> 
    </foo> 
</test>