在VBA中組合詞對象

Question

我在VBA中創建了三個Word對象，它們是; A，B和C

我想這些組合成所謂的一個字對象，D.

我試圖通過一個文件達致這合併無濟於事。

我的源如下：

Set p_appWord = p_appWordContent.Merge(p_appWordGeneral) 

p_appWord是主對象和（p_appWordContentp_appWordGeneral +）是子對象。

Answer 1

這是爲了實現你的願望的三份文件爲例，合併成一個新的：

Dim a As String, b As String, c As String, d As Document 
Dim r As Range 

a = "path to first doc" 
b = "path to second doc" 
c = "path to third doc" 
Set d = Documents.Add 

Set r = d.Content 
r.InsertFile a, Link:=False 
Set r = d.Range(d.Content.End - 1, d.Content.End - 1) 
r.InsertFile b, Link:=False 
Set r = d.Range(d.Content.End - 1, d.Content.End - 1) 
r.InsertFile c, Link:=False 

如果您想爲文件的數目可變做到這一點，你需要循環他們。下面是一個例子，請設置爲Microsoft腳本運行時參考：

Dim d As Document 
Dim r As Range 
Dim fso As FileSystemObject, fol As Folder, f As File 
Dim fc 

Set fso = New FileSystemObject 
Set fol = fso.GetFolder("path to your files") 

Set d = Documents.Add 

For Each f In fol.Files 
    Set r = d.Range(d.Content.End - 1, d.Content.End - 1) 
    r.InsertFile f.Path, Link:=False 
Next f 

編輯 如果你希望當前打開的所有文檔合併成一個沒有遍歷文件，使用這樣的：

Dim d As Document 
Dim r As Range 
Dim allDocs As Variant 

ReDim allDocs(Documents.Count) 

For i = 1 To Documents.Count 
    allDocs(i - 1) = Documents(i).Name 
Next i 

Set d = Documents.Add 

For i = 0 To UBound(allDocs) - 1 
    Documents(allDocs(i)).Range.Copy 
    Set r = d.Range(d.Content.End - 1, d.Content.End - 1) 
    r.Paste 
Next i