需要pandoc批處理命令

Question

我有一個目錄中有子目錄，我試圖將docx轉換爲html。 到目前爲止，我發現這個命令：

@ECHO off 
:selectfile 
:: Clear any preexisting filename variables 
SET filename= 
:: Ask which file we're converting. 
SET /p filename=Which file? (Don't include the .docx file extension): 
CALL pandoc -o -s "%filename%".html --self-contained "%filename%".docx 
GOTO selectfile 

的問題是它的問我的文件名，我必須把這個蝙蝠文件中的每個子文件夾內做的工作。 我想進行一些更改，以便自動檢測子文件夾並將所有docx文件轉換爲具有相同名稱的html文件。 這是可能的傢伙？ 任何人都可以修改此腳本？ 非常感謝。

Answer 1

下面的註釋代碼片段可以幫助：

@echo OFF 
SETLOCAL EnableExtensions 

rem iterate all *.docx recursively 
for /f "delims=" %%G in ('dir /B /S *.docx 2^>NUL') do (

    rem check .html existence 
    if not exist "%%~dpnG.html" (

     rem change the current directory and store the previous path for use by the POPD 
     pushd "%%~dpG" 

     rem `CALL pandoc` is merely displayed for debugging purposes 
     rem    remove ECHO no sooner than debugged   
     ECHO CALL pandoc -o -s "%%~nG.html" --self-contained "%%~nxG" 

     rem change directory back to the path most recently stored by the PUSHD command 
     popd 
    ) 
) 

編輯

我想做出一些改變，這樣它會檢測子 自動和轉換所有的docx文件到html文件 具有相同的名稱。

您可以嵌入上面的代碼片段到你的腳本如下：

@echo OFF 
SETLOCAL EnableExtensions 
:selectfile 
:: Clear any preexisting filename variables 
SET filename= 
:: Ask which file we're converting. 
SET /p filename=Which file? (Don't include the .docx file extension): 

if not defined filename GOTO selectfile 

rem iterate all %filename%.docx recursively 
for /f "delims=" %%G in ('dir /B /S "%filename%.docx" 2^>NUL') do (
    rem check .html existence 
    if not exist "%%~dpnG.html" (
     rem change the current directory and store the previous path for use by the POPD 
     pushd "%%~dpG" 
     rem `CALL pandoc` is merely displayed for debugging purposes 
     rem    remove ECHO no sooner than debugged   
     ECHO CALL pandoc -o -s "%%~nG.html" --self-contained "%%~nxG" 
     rem change directory back to the path most recently stored by the PUSHD command 
     popd 
    ) 
) 

GOTO selectfile 

資源（必讀）：

• （命令參考）An A-Z Index of the Windows CMD command line
• （額外的特殊性）Windows CMD Shell Command Line Syntax
• （%~G等特殊頁）Command Line arguments (Parameters)
• （2>NUL等特殊頁）Redirection