如何使任意SAS格式的字符變量等於數值變量的格式化值？

Question

如果我有一個格式的數值變量，有沒有辦法將格式化的值作爲字符變量？

例如我想寫下如下內容來將10/06/2009打印到屏幕上，但沒有putformatted()功能。

data test; 
    format i ddmmyy10.; 
    i = "10JUN2009"d; 
run; 

data _null_; 
    set test; 
    i_formatted = putformatted(i); /* How should I write this? */ 
    put i_formatted; 
run; 

（很明顯，我可以寫put(i, ddmmyy10.)，但我的代碼需要爲任何格式i恰巧有工作）。

Answer 1

的VVALUE函數格式使用變量相關的格式傳遞給它的變量。下面是使用VVALUE代碼：

data test; 
    format i ddmmyy10.; 
    i = "10JUN2009"d; 
run; 

data _null_; 
    set test; 
    i_formatted = vvalue(i); 
    put i_formatted; 
run; 

雖然cmjohns解決方案是略快於這個代碼，這個代碼更簡單，因爲沒有涉及到宏。

Answer 2

我能做到這一點與宏代碼和sashelp.vcolumn，但它是一個有點繁瑣。

proc sql noprint; 
    select trim(left(format)) into :format 
    from sashelp.vcolumn 
    where libname eq 'WORK' and memname eq 'TEST'; 
run; 

data test2; 
    set test; 
    i_formatted = put(i, &format); 
    put i_formatted; 
run; 

Answer 3

這似乎適用於我試過的一對夫婦。我使用了VARFMT和一個宏函數來檢索給定變量的格式。

data test; 
    format i ddmmyy10. b comma12.; 
    i = "10JUN2009"d; 
    b = 123405321; 
run; 


%macro varlabel(variable) ; 
    %let dsid=%sysfunc(open(&SYSLAST.)) ; 
    %let varnum=%sysfunc(varnum(&dsid,&variable)) ; 
    %let fmt=%sysfunc(varfmt(&dsid,&varnum)); 
    %let dsid=%sysfunc(close(&dsid)) ; 
    &fmt 
%mend varlabel; 

data test2; 
    set test; 
    i_formatted = put(i, %varlabel(i)); 
    b_formatted = put(b, %varlabel(b)); 
    put i_formatted=; 
    put b_formatted=; 
run; 

這給了我：

i_formatted=10/06/2009 
b_formatted=123,405,321 

Answer 4

使用vformat()功能。

/* test data */ 
data test; 
    i = "10jun2009"d; 
    format i ddmmyy10.; 
run; 

/* print out the value using the associated format */ 
data _null_; 
    set test; 
    i_formatted = putn(i, vformat(i)); 
    put i_formatted=; 
run; 
/* on log 
i_formatted=10/06/2099 
*/ 

Answer 5

是的，有一個putformatted（）函數。實際上，有兩個：putc（）和putn（）。 Putc處理字符格式，putn（）數字。您的代碼需要查看格式名稱（所有字符格式和唯一字符格式均以「$」開頭）確定要使用哪種格式。這裏是putc將語法（從交互式的幫助）：

PUTC(source, format.<,w>) 

參數

source 
is the SAS expression to which you want to apply the format. 

format. 
is an expression that contains the character format you want to apply to source. 

w 
specifies a width to apply to the format. 

Interaction: If you specify a width here, it overrides any width specification 
in the format.